2 métodos para contar rápidamente correos electrónicos por remitente en su Outlook

Si desea contar los correos electrónicos por remitente, puede consultar este artículo. Aquí le expondremos 2 enfoques rápidos.

Para saber quién es el remitente más activo, puedes contar los correos electrónicos por remitente. Aunque Outlook no ofrece una función directa para esto, puedes buscar soluciones alternativas, como el Método 1. Si el Método 1 te parece demasiado tedioso, puedes optar por el Método 2. Este es mucho más eficaz, ya que utiliza VBA para contar rápidamente los correos electrónicos por remitente y exportar los resultados a Excel. A continuación, te explicamos ambos métodos en detalle. Aquí usaremos como ejemplo los correos electrónicos de la Bandeja de entrada.

Método 1: obtener recuentos después de agrupar elementos por campo "De"

1. Para empezar, inicie la aplicación Outlook.
2. Luego, abra la carpeta de la bandeja de entrada.
3. A continuación, cambie a la pestaña "Ver".
4. Posteriormente, elija "Desde" en el grupo "Disposición".
5. A la vez, todos los elementos de la bandeja de entrada se han separado en diferentes grupos según los diferentes remitentes.
6. Ahora, para contar los elementos de un remitente específico, puede seleccionar todos los elementos del grupo relacionado y presionar la tecla "Enter". En la advertencia emergente, puede ver el recuento.

Esto significa que es bastante fácil, pero los recuentos de elementos en realidad incluyen los otros tipos de elementos, como invitaciones a reuniones, solicitudes de tareas y recibos, no solo recuentos de correos electrónicos. Por lo tanto, si solo desea contar los correos electrónicos, puede usar la siguiente forma.

Método 2: contar correos electrónicos por remitente con Outlook VBA

1. Para empezar, pulse las teclas “Alt + F11” en Outlook.
2. Luego, habilite la “Biblioteca de objetos de MS Excel” según “Cómo agregar una referencia a una biblioteca de objetos en VBA".
3. A continuación, copie el código siguiente en un módulo no utilizado.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Después de eso, presione la tecla "F5".
4. Cuando finalice la macro, se mostrará un nuevo archivo de Excel.
5. Como puede ver, contiene los recuentos de correos electrónicos de la bandeja de entrada de diferentes remitentes.

Elimine los frustrantes problemas de perspectivas

Tal vez alguna vez haya tenido muchos problemas en Outlook. Para abordarlos de manera efectiva, es posible que desee una forma versátil y poderosa. Sin embargo, de hecho, no existe tal método. Lo que puede hacer es tener cuidado con sus propias operaciones en Outlook y realizar copias de seguridad periódicas. Por supuesto, si es posible, le sugerimos que tenga a mano una herramienta de reparación con experiencia, como DataNumen Outlook Repair. Puede solucionar varios problemas de PST y reparar PST corrupto archivo como una brisa.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperar Sql Server y productos de software de reparación de Outlook. Para más información visite www.datanumen.com