Πώς να αποσυμπιέσετε το .Zip Συνημμένα απευθείας στο Outlook μέσω VBA

Όταν λαμβάνετε ένα συνημμένο στο ".zip" επέκταση αρχείου, αν θέλετε να τα αποσυμπιέσετε, γενικά, θα πρέπει να τα αποθηκεύσετε και να τα αποσυμπιέσετε στην τοπική μονάδα δίσκου. Αλλά πολλοί ελπίζουν να τα αποσυμπιέσουν απευθείας στο Outlook. Αυτό το άρθρο θα σας διδάξει πώς να το αποκτήσετε μέσω VBA.

Πρέπει να έχετε λάβει ποτέ τα συνημμένα που βρίσκονται στο ".zip" επέκταση αρχείου. Για πρόσβαση στα εσωτερικά αρχεία σε ένα zip αρχείο, πρέπει πρώτα να το αποσυμπιέσετε. Σε αυτήν την περίπτωση, όπως συνήθως, πρέπει πρώτα να αποθηκεύσετε το zip αρχείο στην τοπική μονάδα δίσκου και, στη συνέχεια, κάντε δεξί κλικ σε αυτό και επιλέξτε "Εξαγωγή όλων" από το μενού περιβάλλοντος. Στην πραγματικότητα, πολλοί χρήστες προτιμούν να αποσυμπιέσουν το αρχείο απευθείας μέσα στο Outlook. Ωστόσο, το Outlook δεν παρέχει μια τέτοια εγγενή λειτουργία. Ευτυχώς, μπορείτε να ακολουθήσετε τα παρακάτω βήματα για να χρησιμοποιήσετε την VBA για να το πραγματοποιήσετε πανεύκολα.

Αποσυμπιέστε το .Zip Συνημμένα απευθείας στο Outlook

1. Πρώτα, ξεκινήστε την εφαρμογή Outlook.
2. Στη συνέχεια, πατήστε "Alt + F11" συντόμευση πλήκτρου στο παράθυρο του Outlook για πρόσβαση στον επεξεργαστή VBA.
3. Στη συνέχεια, στο παράθυρο "Microsoft Visual Basic for Applications", ανοίξτε μια λειτουργική μονάδα που δεν χρησιμοποιείται.
4. Στη συνέχεια, αντιγράψτε και επικολλήστε τους ακόλουθους κωδικούς VBA σε αυτήν την ενότητα.

Public Sub UnzipFileInOutlook()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objShell As Object
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim strFileName As String
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
 
    'Save & Unzip the zip file in local drive
    Set objShell = CreateObject("Shell.Application")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "yyyy-mm-dd-hh-mm-ss")
    MkDir (strTempFolder)
 
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.FileName
           objAttachment.SaveAsFile (strFilePath)
           objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strFilePath)).Items
        End If
    Next
 
    'Reattach the files extracted from the zip file
    strFileName = Dir(strTempFolder & "\")
 
    While Len(strFileName) > 0
          objMail.attachments.Add (strTempFolder & "\" & strFileName)
          strFileName = Dir
          objMail.Save
    Wend
 
    'Delete the attachments in “.zip” file extension
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           objAttachment.Delete
           objMail.Save
        End If
    Next
 
    'Delete the temp folder and files
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Μετά από αυτό, μπορείτε να προσθέσετε το νέο έργο VBA στη γραμμή εργαλείων γρήγορης πρόσβασης του παραθύρου μηνύματος ως συνήθως.
6. Τέλος, μπορείτε να δοκιμάσετε.

• Αρχικά, ανοίξτε ένα μήνυμα με zip αρχείο στο δικό του παράθυρο.
• Στη συνέχεια, κάντε κλικ στο "Ενέργειες"> "Επεξεργασία μηνύματος".
• Στη συνέχεια, κάντε κλικ στο νέο κουμπί μακροεντολής στη γραμμή εργαλείων γρήγορης πρόσβασης.
• Αμέσως, το zip Το αρχείο θα αποσυμπιεστεί, όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης:

Απαλλαγείτε από ενοχλητικά ζητήματα PST

Αν και το αρχείο PST σε νέα μορφή Unicode υποστηρίζει μέγεθος αρχείου 20 GB, είναι ακόμη συνετό να διατηρείτε το αρχείο όσο το δυνατόν μικρότερο. Είναι επειδή ένα μεγάλο αρχείο PST είναι πολύ πιο επιρρεπές σε διαφθορά. Μόλις το αρχείο PST σας παραβιαστεί, θα πρέπει να καταβάλλετε προσπάθειες ανάκτηση PST δεδομένα. Σε αυτό το σενάριο, δεν έχετε άλλη επιλογή από το να επαναλάβετε σε ένα καλά αποδεδειγμένο και αξιόπιστο εργαλείο όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων επισκευή sql και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com