Τρόπος γρήγορης κατάργησης διπλών παραληπτών από το ηλεκτρονικό ταχυδρομείο του Outlook με VBA

Εάν προσθέσετε ομάδες επαφών στο πεδίο "Προς" του τρέχοντος μηνύματος ηλεκτρονικού ταχυδρομείου, ενδέχεται να υπάρχουν κάποιες διπλές μεταξύ τους. Αυτό το άρθρο θα σας διδάξει πώς να χρησιμοποιήσετε το VBA για να καταργήσετε γρήγορα τους διπλότυπους παραλήπτες.

Κατά τη σύνταξη ενός μηνύματος ηλεκτρονικού ταχυδρομείου, εάν όχι μόνο προσθέτετε επαφές, αλλά και ομάδες επαφών ως παραλήπτες, μερικές φορές, ενδέχεται να υπάρχουν διπλοί παραλήπτες καθώς οι ομάδες επαφών καταρρέουν από προεπιλογή. Σε αυτήν την περίπτωση, εάν θέλετε να μάθετε τα διπλά, πρέπει πρώτα να επεκτείνετε τις ομάδες επαφών και, στη συνέχεια, να συγκρίνετε τους παραλήπτες με μη αυτόματο τρόπο, το οποίο έχει εισαχθεί περίπλοκα στο προηγούμενο άρθρο μου - "Τρόπος κατάργησης διπλότυπων παραληπτών από τα μηνύματα ηλεκτρονικού ταχυδρομείου του Outlook". Χωρίς αμφιβολίες, είναι πολύ κουραστικό. Έτσι, πολλοί χρήστες επιθυμούν έναν γρήγορο τρόπο κατάργησης διπλών παραληπτών. Στα ακόλουθα, θα σας διδάξουμε να το αποκτήσετε με το Outlook VBA.

Γρήγορη κατάργηση διπλότυπων παραληπτών στο email του Outlook

1. Πρώτα, ξεκινήστε την εφαρμογή Outlook.
2. Στη συνέχεια, μεταβείτε στην καρτέλα "Προγραμματιστής" και κάντε κλικ στο κουμπί "Visual Basic" ή απλώς πατήστε τα πλήκτρα "Alt + F11".
3. Στη συνέχεια, στο παράθυρο "Microsoft Visual Basic for Applications", θα μπορούσατε να ανοίξετε μια κενή λειτουργική μονάδα.
4. Στη συνέχεια, αντιγράψτε και επικολλήστε τους ακόλουθους κωδικούς VBA σε αυτήν την ενότητα.

Sub RemoveDuplicateRecipients()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact groups in "To" field
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend
 
    'Remove the duplicate recipients
    For i = objRecipients.Count To 1 Step -1
        For n = (i - 1) To 1 Step -1
            If objRecipients(i).Address = objRecipients(n).Address Then
               objRecipients(i).Delete
               Exit For
            End If
        Next
    Next
End Sub

5. Μετά από αυτό, μπορείτε να προσθέσετε το νέο έργο VBA στη γραμμή εργαλείων γρήγορης πρόσβασης του παραθύρου μηνύματος.
6. Αργότερα πρέπει να ρυθμίσετε το επίπεδο ασφάλειας μακροεντολής του Outlook σε χαμηλό.
7. Τέλος, μπορείτε να δοκιμάσετε.

• Αρχικά, συνθέστε ένα email ως συνήθως.
• Στη συνέχεια, προσθέστε ομάδες επαφών και επαφές στο πεδίο "Προς".
• Στη συνέχεια μπορείτε να κάνετε κλικ στο νέο κουμπί μακροεντολής στη γραμμή εργαλείων γρήγορης πρόσβασης.
• Αμέσως, το Outlook θα επεκτείνει αυτόματα τις ομάδες επαφών και, στη συνέχεια, θα καταργήσει τους διπλότυπους παραλήπτες.

Προστατεύστε τα πολύτιμα δεδομένα σας στο Outlook

Καθώς το Outlook είναι επιρρεπές σε σφάλματα, τα δεδομένα του Outlook είναι ευπαθή σε καταστροφή. Επομένως, πρέπει να κάνετε πολλές προσπάθειες για την προστασία του αρχείου Outlook. Πρώτα απ 'όλα, πρέπει να δημιουργείτε αντίγραφα ασφαλείας του αρχείου PST σε τακτική βάση. Θα διευκολύνει κατεστραμμένο PST επισκευή. Επιπλέον, καλύτερα να προετοιμάσετε ένα ισχυρό εργαλείο επιδιόρθωσης εύχρηστο, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων διόρθωση MDF και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com