Πώς να βρείτε γρήγορα παραγράφους μίας φράσης στο έγγραφο του Word

Σε αυτήν την ανάρτηση, θέλουμε να σας δείξουμε τον γρήγορο τρόπο για να βρείτε όλες τις παραγράφους μιας πρότασης σε ένα έγγραφο του Word μέσω VBA.

Τώρα και τότε, ορισμένα έγγραφα μπορεί να έχουν πολύ συγκεκριμένες απαιτήσεις για τη μορφοποίηση και τις δομές τους. Για παράδειγμα, ενδέχεται να μην επιτρέπεται να έχετε παραγράφους με μία μόνο πρόταση. Αυτές οι παράγραφοι δεν είναι δύσκολο να αναγνωριστούν, αλλά χρειάζεται χρόνος, ειδικά είναι ένα μακρύ έγγραφο.

Σήμερα, θα σας προσφέρουμε τον γρήγορο τρόπο να καθορίσετε όλες τις παραγράφους μιας πρότασης στο έγγραφό σας.

Βρείτε όλες τις παραγράφους μίας φράσης σε ένα έγγραφο

1. Πρώτον, το Word μετρά μια περίοδο ως πρόταση. Έτσι, εάν υπάρχουν λέξεις όπως "Mr." ή «κυρία», το Word το θεωρεί ως πρόταση. Για να αποκλείσετε μια τέτοια απόσπαση της προσοχής, πρέπει να αντικαταστήσετε το "Mr." με το "κ.". Και όταν τελειώσετε να βρείτε την παράγραφο μίας πρότασης, μπορείτε να τις αλλάξετε ξανά. Για να αντικαταστήσετε λέξεις, μπορείτε να ανατρέξετε σε αυτόν τον σύνδεσμο: Πώς να βρείτε και να αντικαταστήσετε πολλά στοιχεία στο έγγραφο του Word
2. Δεύτερον, πατήστε "Alt + F11" για να ενεργοποιήσετε το πρόγραμμα επεξεργασίας VBA.
3. Στη συνέχεια, κάντε κλικ στο "Κανονικό" έργο.
4. Κάντε κλικ στην καρτέλα "Εισαγωγή" στη γραμμή μενού και επιλέξτε "Ενότητα" στο αναπτυσσόμενο μενού.
5. Στη συνέχεια, κάντε διπλό κλικ στη λειτουργική μονάδα για να το ανοίξετε.
6. Επικολλήστε τους ακόλουθους κωδικούς στη λειτουργική μονάδα:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Τελευταίο αλλά όχι το λιγότερο, κάντε κλικ στο κουμπί "Εκτέλεση" ή πατήστε "F5".

Θα λάβετε ένα τέτοιο πλαίσιο μηνύματος, που θα σας λέει ότι έχει γίνει η δουλειά.

Βρείτε όλες τις παραγράφους μίας φράσης σε πολλά έγγραφα

1. Αρχικά, πρέπει να τοποθετήσετε όλα τα έγγραφα-στόχους σε έναν φάκελο.
2. Στη συνέχεια, εγκαταστήστε και εκτελέστε την παρακάτω μακροεντολή:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Στο παράθυρο "Αναζήτηση" ανοιχτό, επιλέξτε το φάκελο στον οποίο διατηρείτε έγγραφα και κάντε κλικ στο "OK".

Στη συνέχεια, η μακροεντολή θα επισημάνει όλες τις παραγράφους μιας πρότασης και θα αφήσει τα έγγραφα ανοιχτά. Εάν ένα έγγραφο δεν περιέχει παράγραφο μίας πρότασης, θα κλείσει. Εκτός αυτού, υπάρχει ένα πλαίσιο μηνύματος, το οποίο δείχνει τον αριθμό των παραγράφων μίας πρότασης σε κάθε έγγραφο.

Αντιμετωπίστε το περιστατικό απώλειας δεδομένων

Τα λάθη του χρήστη και η ξαφνική διακοπή ρεύματος μπορεί να οδηγήσουν στο νεκρό του Word. Ενώ ένα καταρρέον Word δεν μπορεί να επηρεάσει μόνο την καθημερινή εργασία, αλλά και να οδηγήσει σε doc ζημιάΑυτό δεν είναι σε καμία περίπτωση το πιο ενοχλητικό μέρος μιας καταστροφής δεδομένων. Είναι καλύτερο να βρείτε ένα βοηθητικό πρόγραμμα επισκευής για να ανακτήσετε δεδομένα αμέσως.

Εισαγωγή συγγραφέα:

Η Vera Chen είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανακτήσει το excel και pdf επισκευή προϊόντων λογισμικού. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com