Τρόπος γρήγορης εξαγωγής συνολικού χρόνου που ξοδεύεται στα ραντεβού του Outlook σε κάθε κατηγορία χρωμάτων

Εάν θέλετε να δημιουργήσετε μια αναφορά για το συνολικό χρόνο που αφιερώνετε στα ραντεβού σε κάθε κατηγορία χρωμάτων, μπορείτε να χρησιμοποιήσετε τη μέθοδο που παρουσιάζεται σε αυτό το άρθρο. Μπορεί να σας βοηθήσει να το επιτύχετε σε γρήγορο χρόνο χωρίς να χρειάζεται να μετράτε χειροκίνητα.

Πολλοί χρήστες έχουν συνηθίσει να καταγράφουν τις περισσότερες δραστηριότητές τους στο ημερολόγιο του Outlook. Επίσης, για να τις διαχειρίζονται και να τις διαφοροποιούν πιο εύκολα, αντιστοιχίζουν κατηγορίες σε κάθε μία από αυτές. Σε αυτήν την περίπτωση, ορισμένοι χρήστες θα ήθελαν να δημιουργήσουν μια αναφορά που να δείχνει τον συνολικό χρόνο που αφιερώνεται στα στοιχεία του ημερολογίου σε κάθε κατηγορία χρώματος. Αναμφίβολα, είναι δύσκολο να μετρήσετε και να εισαγάγετε δεδομένα χειροκίνητα. Επομένως, εδώ θα μοιραστούμε έναν τρόπο με τον οποίο μπορείτε να ολοκληρώσετε αυτήν την εργασία με ένα απλό κλικ.

Εξαγωγή συνολικού χρόνου που ξοδεύεται στα ραντεβού σε κάθε κατηγορία χρωμάτων

1. Πρώτα, ξεκινήστε την εφαρμογή Outlook.
2. Στη συνέχεια, μετά την είσοδο στο παράθυρο του Outlook, μπορείτε να πατήσετε τα κουμπιά "Alt + F11".
3. Στη συνέχεια, θα έχετε πρόσβαση στο παράθυρο "Microsoft Visual Basic for Applications".
4. Στη συνέχεια, θα πρέπει να ενεργοποιήσετε τη «Βιβλιοθήκη αντικειμένων του Microsoft Excel». Μπορείτε να κάνετε κλικ στα «Εργαλεία» > «Αναφορά» για να την ενεργοποιήσετε.
5. Στη συνέχεια, θα πρέπει να βρείτε και να ανοίξετε μια ενότητα που δεν χρησιμοποιείται.
6. Μετά από αυτό, πρέπει να αντιγράψετε τον ακόλουθο κώδικα VBA σε αυτήν την ενότητα.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Τέλος, μπορείτε να ενεργοποιήσετε αυτήν τη μακροεντολή, ανεξάρτητα από το κάνοντας κλικ στο εικονίδιο «Εκτέλεση» στη γραμμή εργαλείων ή πατώντας το κουμπί «F5».
8. Στη συνέχεια, θα σας ζητηθεί να επιλέξετε ένα συγκεκριμένο ημερολόγιο.
9. Αφού επιλέξετε και πατήσετε "OK", η μακροεντολή θα συνεχίσει να εκτελείται. Αφού τελειώσει, θα υπάρχει ένα νέο αρχείο Excel που θα εμφανίζεται στο παρασκήνιο.
10. Μπορείτε να αποκτήσετε πρόσβαση σε αυτό. Θα μοιάζει με το ακόλουθο στιγμιότυπο οθόνης:

Παρακολουθήστε τις πιθανές απειλές γύρω από το Outlook

Οι χρήστες του Outlook πρέπει να προσέχουν όλους τους πιθανούς κινδύνους, συμπεριλαμβανομένων άγνωστων συνημμένων email, ενσωματωμένων συνδέσμων και ανθρώπινων σφαλμάτων. Διαφορετικά, το Outlook μπορεί να καταστραφεί ανά πάσα στιγμή. Επίσης, η τακτική δημιουργία αντιγράφων ασφαλείας δεδομένων του Outlook και η διατήρηση ενός εξειδικευμένου εργαλείου επιδιόρθωσης είναι απαραίτητα. DataNumen Outlook Repair είναι ένα από τα πιο συνιστώμενα εργαλεία επιδιόρθωσης. Μπορεί επιδιορθώστε το Outlook προβλήματα σε ένα άγχος.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο MDF και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com