Τρόπος γρήγορης εξαγωγής ενός email του Outlook ως αρχείου εικόνας

Ορισμένοι χρήστες θα ήθελαν να εξάγουν ένα email Outlook ως αρχείο εικόνας, όπως ένα αρχείο jpg. Επομένως, σε αυτό το άρθρο, θα σας παρουσιάσουμε πώς να το αποκτήσετε μέσω του κώδικα Outlook VBA.

Πρέπει να έχετε μάθει διάφορα κόλπα για την εξαγωγή ενός email ως αρχείο κειμένου, έγγραφο του Word και ούτω καθεξής. Τότε, τι γίνεται με την εξαγωγή ενός email ως εικόνα όπως το αρχείο JPG; Προφανώς, το Outlook δεν έχει αυτήν τη λειτουργία. Όμως, στη συνέχεια, θα μοιραστούμε μαζί σας ένα γρήγορο μέσο.

Εξαγάγετε γρήγορα ένα Outlook email ως αρχείο εικόνας

1. Για αρχή, ξεκινήστε την εφαρμογή Outlook.
2. Στη συνέχεια, στο κύριο παράθυρο του Outlook, αποκτήστε πρόσβαση στον επεξεργαστή VBA σύμφωνα με το άρθρο - "Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
3. Στη συνέχεια, ενεργοποιήστε τις "Βιβλιοθήκη αντικειμένων MS Word" και "MS PowerPoint Βιβλιοθήκη αντικειμένων" αναφερόμενος στο άρθρο – "Πώς να προσθέσετε μια αναφορά βιβλιοθήκης αντικειμένων σε VBA".
4. Στη συνέχεια, αντιγράψτε και επικολλήστε τον ακόλουθο κώδικα VBA σε μια κενή μονάδα.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Μετά από αυτό, πρέπει να προσθέσετε τη μακροεντολή στη γραμμή εργαλείων γρήγορης πρόσβασης.
6. Στη συνέχεια, θα μπορούσατε να κλείσετε το πρόγραμμα επεξεργασίας VBA.
7. Αργότερα, επιλέξτε ένα email και πατήστε το κουμπί μακροεντολής στη Γραμμή εργαλείων γρήγορης πρόσβασης.
8. Όταν ολοκληρωθεί η μακροεντολή, μπορείτε να μεταβείτε στον προκαθορισμένο τοπικό φάκελο για να βρείτε το εξαγόμενο αρχείο εικόνας από αυτό το μήνυμα ηλεκτρονικού ταχυδρομείου.

Ανάκτηση δεδομένων του Outlook από κατεστραμμένο αρχείο

Μπορεί να είστε αρκετά απογοητευμένοι εάν το αρχείο του Outlook σας υποστεί σοβαρή ζημιά. Σε αυτό το σενάριο, θα προχωρήσετε στην εξαγωγή δεδομένων του Outlook από το παραβιασμένο αρχείο. Ορισμένοι χρήστες θα έχουν την τάση να χρησιμοποιούν το εργαλείο επιδιόρθωσης εισερχομένων. Ωστόσο, τις περισσότερες φορές, δεν θα έχει αποτελέσματα. Επομένως, καλύτερα να διατηρήσετε ένα ισχυρό και αξιόπιστο αρχείο. Διόρθωση PST εργαλείο, όπως DataNumen Outlook Repair. Μπορεί να σαρώσει το κατεστραμμένο αρχείο και να πάρει πίσω τα μέγιστα δεδομένα χωρίς φασαρία.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων διόρθωση MDF και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com