Πώς να μετατρέψετε γρήγορα όλες τις ενσωματωμένες εικόνες σε συνημμένα στο email σας στο Outlook

Εάν θέλετε να αλλάξετε γρήγορα όλες τις εικόνες που είναι ενσωματωμένες στο σώμα μηνυμάτων σε συνημμένα email, δεν χρειάζεται να αφαιρέσετε και να επισυνάψετε ξανά με μη αυτόματο τρόπο. Μπορείτε απλώς να χρησιμοποιήσετε το κομμάτι του κώδικα VBA που εκτίθεται σε αυτό το άρθρο.

Μερικές φορές, μπορεί να θέλετε να μετατρέψετε κατά παρτίδα όλες τις ενσωματωμένες εικόνες σε συνημμένα. Για παράδειγμα, πάρα πολλές εικόνες στο σώμα του μηνύματος θα διακόψουν την ανάγνωση των κειμένων στο σώμα. Επομένως, θέλετε να τα αφαιρέσετε από το σώμα του email και να τα προσθέσετε ως συνημμένα. Φυσικά, μπορείτε να το κάνετε χειροκίνητα. Αλλά πρέπει να είναι πιο εύχρηστο εάν κάποια εργαλεία ή κωδικοί VBA μπορούν να το πάρουν αυτό με μια κίνηση. Εδώ θα σας αποκαλύψουμε έναν τέτοιο κωδικό VBA.

Γρήγορη μετατροπή όλων των ενσωματωμένων εικόνων σε συνημμένα

1. Αρχικά, ξεκινήστε το πρόγραμμα Outlook.
2. Στη συνέχεια, μπορείτε να μεταβείτε στην καρτέλα "Προγραμματιστής" και να πατήσετε το κουμπί "Visual Basic".
3. Στη συνέχεια, θα μπείτε στο παράθυρο του Outlook VBA editor.
4. Στη συνέχεια, πρέπει να αντιγράψετε τον ακόλουθο κώδικα VBA σε μια κενή μονάδα.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Μετά από αυτό, θα πρέπει να επιβεβαιώσετε ότι το Outlook έχει ρυθμιστεί ώστε να επιτρέπει μακροεντολές.
6. Προαιρετικά, εάν το απαιτείτε συχνά, θα πρέπει να προσθέσετε τη νέα μακροεντολή στη γραμμή εργαλείων γρήγορης πρόσβασης για μελλοντικό βολικό έλεγχο.
7. Τελικά μπορείτε να δοκιμάσετε. Επιλέξτε ή ανοίξτε ένα μήνυμα ηλεκτρονικού ταχυδρομείου και, στη συνέχεια, εκτελέστε τη μακροεντολή κάνοντας κλικ στο κουμπί νέας μακροεντολής στη Γραμμή εργαλείων γρήγορης πρόσβασης.
8. Αμέσως, όλες οι ενσωματωμένες εικόνες θα αλλάξουν σε συνημμένα ως το ακόλουθο στιγμιότυπο οθόνης:

Κόλπα για την προστασία των πολύτιμων δεδομένων του Outlook

Όπως όλοι γνωρίζουμε, το αρχείο PST του Outlook είναι το ίδιο ευάλωτο με τα κοινά αρχεία, όπως έγγραφα Word ή υπολογιστικά φύλλα Excel. Επομένως, θα πρέπει να προσέχετε για όλους τους κινδύνους γύρω από το αρχείο PST, όπως ιούς ή ακατάλληλους χειρισμούς. Επομένως, πρέπει να κάνετε τακτικά αντίγραφα ασφαλείας δεδομένων για το αρχείο PST. Επίσης, αν μπορείτε να το αντέξετε οικονομικά, είναι συνετό να διατηρήσετε ένα στιβαρό Επισκευή του Outlook εύχρηστο εργαλείο, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση mdf και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com