Πώς να λάβετε μια ειδοποίηση εάν δεν λάβετε την απάντηση συγκεκριμένου email εντός του αναμενόμενου χρόνου

Αυτό το άρθρο θα σας διδάξει ένα γρήγορο τέχνασμα χρησιμοποιώντας το VBA για να επιτρέψετε στο Outlook να σας ζητήσει αυτόματα εάν θα στείλετε ένα email ειδοποίησης όταν δεν έχετε λάβει την απάντηση ενός συγκεκριμένου email εντός συγκεκριμένης χρονικής περιόδου.

Μερικές φορές, για τα εξαιρετικά σημαντικά μηνύματα ηλεκτρονικού ταχυδρομείου, σίγουρα θα ανυπομονούμε για τις απαντήσεις του. Με άλλα λόγια, πρέπει να ελπίζετε ότι ο παραλήπτης μπορεί να σας απαντήσει το συντομότερο δυνατό. Διαφορετικά, αρκεί να μην έχετε λάβει ακόμη την απάντηση εντός του αναμενόμενου χρόνου σας, θα στείλετε ξανά ένα email ειδοποίησης παρακολούθησης στον παραλήπτη. Ως εκ τούτου, ως απάντηση σε αυτήν την απαίτηση, εδώ θα παρουσιάσουμε μια μέθοδο που χρησιμοποιεί το VBA για να κάνει το Outlook να προειδοποιεί αυτόματα και να σας προτρέπει σε μια τέτοια περίπτωση. Διαβάστε παρακάτω για να λάβετε τα περίπλοκα βήματα και τους κωδικούς.

Λάβετε ειδοποίηση εάν δεν λαμβάνετε την απάντηση συγκεκριμένου email εντός του αναμενόμενου χρόνου

1. Από την αρχή, ξεκινήστε το Outlook σας.
2. Στη συνέχεια, πρέπει να ορίσετε έναν συγκεκριμένο χρόνο υπενθύμισης στο συγκεκριμένο email.

• Πρώτον, κάντε δεξί κλικ στο συγκεκριμένο email.
• Στη συνέχεια, επιλέξτε "Παρακολούθηση"> "Προσθήκη Υπενθύμισης".
• Στο παράθυρο διαλόγου, μπορείτε να ορίσετε την ώρα υπενθύμισης ίδια με τη συγκεκριμένη ώρα εντός της οποίας θέλετε να λάβετε την απάντησή της.

3. Μετά από αυτό, πατήστε τα πλήκτρα "Alt + F11" για πρόσβαση στο πρόγραμμα επεξεργασίας του Outlook VBA.
4. Στη συνέχεια στο νέο παράθυρο, ανοίξτε το έργο "ThisOutlookSession" και αντιγράψτε τους παρακάτω κωδικούς.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Στη συνέχεια, υπογράψτε αυτόν τον κωδικό.
6. Αργότερα αλλάξτε τη ρύθμιση μακροεντολής του Outlook για να επιτρέψετε τις μακροεντολές με ψηφιακή υπογραφή
7. Τελικά, επανεκκινήστε το Outlook για να ενεργοποιήσετε τη νέα μακροεντολή. Από εδώ και στο εξής, το Outlook θα λειτουργεί ως εξής:

• Εάν έχετε λάβει την απάντηση του συγκεκριμένου email πριν εμφανιστεί η υπενθύμισή του, το Outlook θα διαγράψει αυτόματα τη σημαία και θα απενεργοποιήσει την υπενθύμιση.
• Εάν δεν έχετε λάβει την απάντηση όταν ενεργοποιηθεί η υπενθύμισή του, το Outlook θα σας ρωτήσει εάν θα στείλετε ένα email ειδοποίησης παρακολούθησης. Εάν επιλέξετε "Ναι", το email θα σταλεί. Εάν επιλέξετε "Όχι", το μήνυμα θα εξαφανιστεί ταυτόχρονα.

Επιλύστε τα ενοχλητικά ζητήματα του Outlook

Καθώς το Outlook είναι επιρρεπές σε σφάλματα, προκειμένου να αποφευχθεί Διαφθορά στο Outlook, καλύτερα να βασίζεσαι όχι μόνο στο εργαλείο εισερχομένων, το Scanpst.exe. Θα πρέπει να προετοιμάσετε ένα άλλο ισχυρό και αξιόπιστο εργαλείο επισκευής, όπως DataNumen Outlook Repair, που μπορεί να απορρίψει τα ενοχλητικά ζητήματα που δεν μπορεί να επιλύσει το Scanpst.exe.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων sql διαφθορά και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com