Τρόπος μαζικής κατάργησης όλων των διευθύνσεων ηλεκτρονικού ταχυδρομείου με συγκεκριμένο τομέα από τις επαφές σας στο Outlook

Κατά καιρούς, μπορεί να ελπίζετε να καταργήσετε όλες τις διευθύνσεις ηλεκτρονικού ταχυδρομείου με έναν συγκεκριμένο τομέα από τις επαφές σας. Σε αυτήν την περίπτωση, πρέπει να είστε απρόθυμοι να το κάνετε αυτό ένα προς ένα. Έτσι, αυτό το σελost θα σας διδάξει μια πολύ πιο έξυπνη μέθοδο.

Για παράδειγμα, μια εταιρεία αλλάζει το όνομά της. Εν τω μεταξύ, ο τομέας της εταιρείας αλλάζει επίσης. Ωστόσο, στο Outlook, έχετε αποθηκεύσει πολλές επαφές σε αυτήν την εταιρεία, των οποίων οι διευθύνσεις ηλεκτρονικού ταχυδρομείου είναι με τον παλιό τομέα. Φυσικά, αυτές οι διευθύνσεις ηλεκτρονικού ταχυδρομείου δεν είναι πλέον έγκυρες. Επομένως, σε αυτήν την περίπτωση, εάν θέλετε να καταργήσετε αυτές τις διευθύνσεις ηλεκτρονικού ταχυδρομείου με μία κίνηση, μπορείτε να χρησιμοποιήσετε τον ακόλουθο τρόπο.

Μαζική κατάργηση όλων των διευθύνσεων ηλεκτρονικού ταχυδρομείου με συγκεκριμένο τομέα από τις επαφές

1. Για ωςtart, αποκτήστε πρόσβαση στο πρόγραμμα επεξεργασίας του Outlook VBA με συντόμευση πλήκτρου - "Alt + F11".
2. Στη συνέχεια, στο νέο παράθυρο, τοποθετήστε τον ακόλουθο κώδικα VBA σε μια κενή μονάδα.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Μετά από αυτό, τοποθετήστε τον κέρσορα στην υπορουτίνα "BatchRemoveAllEmailAddressesInSpecificDomain".
4. Τέλος, κάντε κλικ στο πλήκτρο "F5" για να ενεργοποιήσετε αυτήν τη μακροεντολή.
5. Στη συνέχεια, εισαγάγετε τον συγκεκριμένο τομέα στο αναδυόμενο παράθυρο διαλόγου.
6. Αφού κάνετε κλικ στο "OK", θα εκτελεστεί η μακροεντολή.
7. Όταν τελειώσει, θα λάβετε ένα μήνυμα σχετικά με τα αποτελέσματα.
8. Τώρα, μπορείτε να ελέγξετε τις επαφές. Όλες οι διευθύνσεις email με τον συγκεκριμένο τομέα πρέπει να έχουν εξαφανιστεί.

Διατηρήστε το αρχείο Outlook

Με όλο και περισσότερους κινδύνους που περιβάλλουν το Outlook, είναι όλο και πιο δύσκολο να προστατεύσετε τα πολύτιμα δεδομένα σας στο Outlook. Για παράδειγμα, όχι μόνο πρέπει να διατηρείτε τακτικά αντίγραφα ασφαλείας δεδομένων, αλλά και να προσέχετε τις λειτουργίες σας. Δεν είναι σοφό να εμπιστεύεστε εύκολα τυχόν μηνύματα ηλεκτρονικού ταχυδρομείου από άγνωστους αποστολείς. Διαφορετικά, εάν μεταφέρει ιό, το αρχείο Outlook θα μολυνθεί. Εκείνη τη στιγμή, πρέπει να προσπαθήσετε Επισκευή του Outlook μέσω ενός αξιόλογου εργαλείου επιδιόρθωσης, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση Sql Server και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com