Αυτό το άρθρο θα σας διδάξει πώς να αφήσετε το Outlook να μετρά αυτόματα πόσα μηνύματα ηλεκτρονικού ταχυδρομείου λαμβάνετε καθημερινά και να γράφετε τον αριθμό σε ένα αρχείο Excel.
Πολλοί χρήστες υποχρεούνται να υπολογίζουν τον συνολικό αριθμό των email που λαμβάνουν κάθε μέρα. Επιπλέον, για πιο βολικό έλεγχο στο μέλλον, πολλοί έχουν συνηθίσει να καταγράφουν τη συνολική καταμέτρηση σε ένα αρχείο Excel. Σε αυτήν την περίπτωση, φυσικά μπορείτε να επιλέξετε να μετράτε και να καταγράφετε χειροκίνητα κάθε μέρα. Ωστόσο, είναι λίγο ενοχλητικό. Και μπορεί να ξεχάσετε να το κάνετε μερικές φορές. Επομένως, πρέπει να θέλετε μια εύχρηστη μέθοδο, η οποία μπορεί να κάνει το Outlook να το κάνει αυτόματα. Σε απάντηση σε αυτήν την απαίτηση, θα σας διδάξουμε πώς να χρησιμοποιήσετε το VBA για να το πραγματοποιήσετε στα ακόλουθα.
Αυτόματη καταγραφή του συνολικού αριθμού των εισερχόμενων μηνυμάτων ηλεκτρονικού ταχυδρομείου κάθε μέρα σε ένα αρχείο Excel
- Στην αρχή, ξεκινήστε την εφαρμογή Outlook.
- Στη συνέχεια, πατήστε "Alt + F11" συντομεύσεις πλήκτρων στο κύριο παράθυρο του Outlook.
- Στη συνέχεια, στο αναδυόμενο παράθυρο του προγράμματος επεξεργασίας VBA, ανοίξτε το έργο "ThisOutlookSession".
- Στη συνέχεια, αντιγράψτε και επικολλήστε τους ακόλουθους κωδικούς VBA σε αυτό το έργο.
Private Sub Application_Reminder(ByVal Item As Object)
If Item.Class = olTask And Item.Subject = "Update Email Count" Then
Call GetAllInboxFolders
End If
End Sub
Private Sub GetAllInboxFolders()
Dim objInboxFolder As Outlook.Folder
Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim nNextEmptyRow As Integer
Dim lEmailCount As Long
lEmailCount = 0
Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
Call UpdateEmailCount(objInboxFolder, lEmailCount)
‘Change the path to the Excel file
strExcelFile = "E:\Email\Email Count.xlsx"
Set objExcelApp = CreateObject("Excel.Application")
Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
'Add the values into the columns
objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
'Fit the columns from A to C
objExcelWorksheet.Columns("A:C").AutoFit
'Save the changes and close the Excel file
objExcelWorkbook.Close SaveChanges:=True
End Sub
Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
Dim objItems As Outlook.Items
Dim objItem As Object
Dim objMail As Outlook.MailItem
Dim strDay As String
Dim strReceivedDate As String
Dim lEmailCount As Long
Dim objSubFolder As Outlook.Folder
Set objItems = objFolder.Items
objItems.SetColumns ("ReceivedTime")
strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
For Each objItem In objItems
If objItem.Class = olMail Then
Set objMail = objItem
strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
If strReceivedDate = strDay Then
lCurEmailCount = lCurEmailCount + 1
End If
End If
Next
'Process the subfolders in the folder recursively
If (objFolder.Folders.Count > 0) Then
For Each objSubFolder In objFolder.Folders
Call UpdateEmailCount(objSubFolder, lCurEmailCount)
Next
End If
End Sub
- Στη συνέχεια, υπογράψτε αυτόν τον κωδικό και αλλάξτε τις ρυθμίσεις μακροεντολών του Outlook για να επιτρέψετε υπογεγραμμένες μακροεντολές.
- Μετά από αυτό, πρέπει να δημιουργήσετε μια επαναλαμβανόμενη εργασία σε καθημερινή βάση.
- Αρχικά, κάντε κλικ στο κουμπί "Νέα εργασία" στο παράθυρο εργασιών.
- Στο αναδυόμενο παράθυρο New Task, κάντε κλικ στο κουμπί "Επανάληψη".
- Στη συνέχεια, στο επόμενο παράθυρο διαλόγου, επιλέξτε "Καθημερινά", "Κάθε 1 ημέρα" και "Χωρίς ημερομηνία λήξης" και τέλος πατήστε "ΟΚ".
- Αργότερα αλλάξτε το θέμα της εργασίας και την υπενθύμιση σύμφωνα με τις ανάγκες σας.
- Τελικά κάντε κλικ στο κουμπί "Αποθήκευση και κλείσιμο".
- Από τώρα και στο εξής, κάθε φορά που ειδοποιεί η υπενθύμιση αυτής της εργασίας, το Outlook θα μετρήσει αυτόματα τα μηνύματα που ελήφθησαν χθες και, στη συνέχεια, θα εγγράψει τον αριθμό στο αρχείο Excel, όπως το ακόλουθο στιγμιότυπο οθόνης:
Διαφυγή από μόνιμη απώλεια δεδομένων PST
Κανείς δεν είναι πρόθυμος να δεχτεί μόνιμη απώλεια δεδομένων PST. Ωστόσο, το αρχείο Outlook PST είναι επιρρεπές σε καταστροφή. Επομένως, θα πρέπει να λάβετε επαρκείς προφυλάξεις, όπως να κάνετε ένα συνεπές και ενημερωμένο αντίγραφο ασφαλείας δεδομένων PST και να διατηρείτε ένα ισχυρό Ανάκτηση PST εργαλείο κοντά, όπως DataNumen Outlook Repair.
Εισαγωγή συγγραφέα:
Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων επισκευή sql και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com