Τρόπος αυτόματης απενεργοποίησης των υπερσυνδέσμων στα εισερχόμενα μηνύματα ηλεκτρονικού ταχυδρομείου του Outlook από άγνωστους αποστολείς

Για να αποκλείσετε κακόβουλους συνδέσμους, καλύτερα να ρυθμίσετε το Outlook ώστε να απενεργοποιεί αυτόματα τους υπερσυνδέσμους στα εισερχόμενα μηνύματα ηλεκτρονικού ταχυδρομείου από άγνωστους αποστολείς. Αυτό το άρθρο θα αποκαλύψει ένα κομμάτι κωδικών VBA που μπορούν να σας βοηθήσουν να το αποκτήσετε σαν φελλό.

Πολλοί χρήστες έχουν παραπονεθεί ότι ιοί που μεταδίδονται μέσω email επιτέθηκαν στο αρχείο τους Outlook. Τις περισσότερες φορές, είναι επειδή εμπιστεύονται εύκολα αυτά τα μηνύματα ηλεκτρονικού ταχυδρομείου από τους άγνωστους αποστολείς. Έτσι κατεβάζουν ή κάνουν κλικ στους υπερσυνδέσμους στα mail. Τώρα, στη συνέχεια, θα μοιραστούμε μια μέθοδο. Είναι σε θέση να επιτρέψει στο Outlook να απενεργοποιήσει αυτόματα τους υπερσυνδέσμους εισερχόμενων email από άγνωστους αποστολείς. Εάν έχετε τέτοιες ανάγκες, διαβάστε παρακάτω για περισσότερες λεπτομέρειες.

Αυτόματη απενεργοποίηση υπερσυνδέσμων σε εισερχόμενα μηνύματα ηλεκτρονικού ταχυδρομείου από άγνωστους αποστολείς

1. Για αρχή, στο Outlook, μεταβείτε στον επεξεργαστή VBA πατώντας "Alt + F11".
2. Στη συνέχεια, στη νέα οθόνη, προσθέστε το αντικείμενο "MS VBScript Regular Expressions" σύμφωνα με την ανάρτηση "Πώς να προσθέσετε μια αναφορά βιβλιοθήκης αντικειμένων σε VBA".
3. Στη συνέχεια, αντιγράψτε και επικολλήστε τον ακόλουθο κώδικα στο έργο "ThisOutlookSession".

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Στη συνέχεια, ενεργοποιήστε αυτήν τη μακροεντολή είτε επανεκκινώντας το Outlook είτε πατώντας το πλήκτρο "F5" στην υπορουτίνα "Application_Startup".
5. Από τότε, κάθε φορά που ένα μήνυμα ηλεκτρονικού ταχυδρομείου που προέρχεται από τον αποστολέα που δεν είναι αποθηκευμένο στον προεπιλεγμένο φάκελο "Επαφές" μπαίνει στο Inbox, το Outlook θα απενεργοποιεί αυτόματα τους υπερσυνδέσμους σε αυτό.

Αρκετά θέματα αναγκαιότητας στην προστασία του Outlook

Καθώς το Outlook είναι επιρρεπές σε ζημιά, είναι αρκετά δύσκολο να προστατεύσετε το αρχείο του Outlook. Εδώ θα παραθέσουμε πολλά απαραίτητα κατά την προστασία δεδομένων του Outlook. Πρώτα απ 'όλα, πρέπει να δημιουργείτε αντίγραφα ασφαλείας των δεδομένων του Outlook σε τακτική βάση. Επιπλέον, είναι απαραίτητο να προσέχετε όλους τους πιθανούς κινδύνους, όπως κακόβουλα συνημμένα ή υπερσυνδέσμους. Τελευταίο αλλά εξίσου σημαντικό, θα πρέπει να προετοιμάσετε ένα ισχυρό εργαλείο επιδιόρθωσης του Outlook εκ των προτέρων, όπως π.χ DataNumen Outlook Repair. Σίγουρα θα σας φανεί χρήσιμο όταν το χρειαστείτε επισκευή PST αρχείο αλλά το εργαλείο επιδιόρθωσης εισερχομένων αποδεικνύει αποτυχία.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο MDF και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com