Πώς να εφαρμόσετε αυτόματα τις κατηγορίες ενός μηνύματος ηλεκτρονικού ταχυδρομείου σε όλες τις απαντήσεις και τις προωθήσεις του στο Outlook

Λύσεις του Outlook Σεπτέμβριος 29, 2025

Όταν απαντάτε ή προωθείτε ένα μήνυμα ηλεκτρονικού ταχυδρομείου, ίσως θέλετε να εφαρμόσετε τις ίδιες κατηγορίες. Σε αυτό το άρθρο, θα σας μάθουμε να το συνειδητοποιήσετε με τον κώδικα VBA.

Εάν έχετε συνηθίσει να εκχωρείτε τις ίδιες κατηγορίες χρωμάτων του αρχικού μηνύματος ηλεκτρονικού ταχυδρομείου σε όλες τις απαντήσεις και τις προωθήσεις του, γιατί δεν αφήνετε το Outlook να το επιτύχει αυτόματα; Παρόλο που το Outlook δεν παρέχει μια τέτοια άμεση δυνατότητα, εξακολουθείτε να μπορείτε να την αποκτήσετε με τη βοήθεια κώδικα VBA. Στη συνέχεια, θα σας εκθέσουμε τα λεπτομερή βήματα και τον κώδικα.

Αυτόματη εφαρμογή των κατηγοριών ενός email σε όλες τις απαντήσεις και προωθήσεις του

Στην αρχή, ξεκινήστε την εφαρμογή Outlook.
Στη συνέχεια, πατήστε τα πλήκτρα "Alt + F11" για να εκτελέσετε το πρόγραμμα επεξεργασίας Outlook VBA.
Στη συνέχεια, αντιγράψτε τον ακόλουθο κώδικα VBA στο έργο "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

Στη συνέχεια, επανεκκινήστε το Outlook για να ενεργοποιήσετε αυτό το έργο.
Από τότε, μπορείτε να το δοκιμάσετε ακολουθώντας τα παρακάτω βήματα.

Πρώτα, επιλέξτε ένα email και πατήστε το κουμπί "Προώθηση".
Στη συνέχεια, θα εμφανιστεί ένα email προώθησης, στο οποίο μπορείτε να μεταβείτε στην καρτέλα "Επιλογές" και να πατήσετε το εικονίδιο επέκτασης στην κάτω δεξιά γωνία της ομάδας "Περισσότερες επιλογές".
Στη συνέχεια, στο αναδυόμενο παράθυρο διαλόγου "Ιδιότητες", μπορείτε να δείτε ότι αυτό το email έχει εκχωρηθεί με τις ίδιες κατηγορίες χρωμάτων με το αρχικό email.

Διορθώστε το κατεστραμμένο αρχείο του Outlook

Δεδομένου του γεγονότος ότι το Outlook είναι ευάλωτο, πρέπει να προβείτε σε πολλές ενέργειες για να αποφύγετε την απώλεια δεδομένων του Outlook. Για παράδειγμα, πρέπει να δημιουργείτε περιοδικά αντίγραφα ασφαλείας δεδομένων. Επιπλέον, είναι απαραίτητο να προσέχετε άγνωστα μηνύματα ηλεκτρονικού ταχυδρομείου, συμπεριλαμβανομένων των ενσωματωμένων συνδέσμων ή των συνημμένων. Τελευταίο αλλά εξίσου σημαντικό, θα πρέπει να αποκτήσετε ένα κορυφαίο εξωτερικό εργαλείο επιδιόρθωσης, όπως π.χ DataNumen Outlook Repair. Είναι σε θέση να σας βοηθήσει να ανακτήσετε τα μέγιστα δεδομένα από κατεστραμμένο Outlook αρχείο.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων SQL Server σταθερός και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com