3 γρήγοροι τρόποι διαγραφής κενών γραμμών και στηλών στον πίνακα του Word

Σε αυτήν την ανάρτηση, θα σας εξηγήσουμε 3 γρήγορους τρόπους για να διαγράψετε κενές γραμμές και στήλες στον πίνακα του Word.

Οι πίνακες είναι απαραίτητοι για ένα έγγραφο, ειδικά για την αποθήκευση διαφόρων τύπων δεδομένων. Μερικές φορές, ένας μακρύς πίνακας μπορεί να ξεπεράσει μια σελίδα και να επεκταθεί σε αρκετές. Έτσι, όταν ένας πίνακας γίνει μακρύς και περίπλοκος, υπάρχουν μέτρα που μπορείτε να κάνετε για να το απλοποιήσετε. Για παράδειγμα, μπορείτε να διαγράψετε περιττές κενές γραμμές και στήλες.

Ακολουθούν 3 μέθοδοι που μπορείτε να χρησιμοποιήσετε.

Μέθοδος 1: Διαγραφή κενών γραμμών και στηλών χειροκίνητα

1. Αρχικά, επιλέξτε μια σειρά ή μια στήλη σε κενό.
2. Στη συνέχεια, κάντε δεξί κλικ για να λάβετε το μενού με βάση τα συμφραζόμενα. Στο μενού, επιλέξτε "Διαγραφή σειρών" ή "Διαγραφή στηλών" ανάλογα.

Δυστυχώς, δεν μπορείτε να επιλέξετε πολλές μη διαδοχικές σειρές ή στήλες και να τις διαγράψετε μαζί με αυτόν τον τρόπο. Για αυτήν την απαίτηση, μπορείτε να ανατρέξετε στο προηγούμενο άρθρο μας: 5 γρήγορες μέθοδοι για τη μαζική διαγραφή πολλαπλών σειρών ή στηλών στον πίνακα του Word

Μέθοδος 2: Διαγραφή παρτίδας όλων των κενών γραμμών και στηλών σε έναν πίνακα

Η μέθοδος 1 έχει τον περιορισμό της. Έτσι, θα σας προσφέρουμε τον τρόπο κατάργησης μαζικών γραμμών και στηλών σε έναν πίνακα μέσω κωδικών VBA.

1. Αρχικά, τοποθετήστε τον κέρσορα μέσα σε έναν πίνακα προορισμού.
2. Δεύτερον, ενεργοποιήστε τον επεξεργαστή VBA πατώντας "Alt + F11".
3. Στο πρόγραμμα επεξεργασίας, κάντε κλικ πρώτα στο "Normal" έργο
4. Στη συνέχεια, κάντε κλικ στην καρτέλα "Εισαγωγή" στη γραμμή μενού.
5. Στο αναπτυσσόμενο μενού, επιλέξτε "Ενότητα".
6. Κάντε διπλό κλικ στη λειτουργική μονάδα για να την ανοίξετε και επικολλήστε τους ακόλουθους κωδικούς εκεί:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Τέλος, κάντε κλικ στο κουμπί "Εκτέλεση" στη γραμμή μενού ή πατήστε "F5".

Σε δευτερόλεπτα, θα αφαιρεθούν όλες οι κενές γραμμές και στήλες σε αυτόν τον πίνακα.

Μέθοδος 3: Διαγραφή παρτίδας όλων των κενών γραμμών και στηλών σε όλους τους πίνακες σε ένα έγγραφο

1. Πρώτα απ 'όλα, επαναλάβετε τα βήματα στη μέθοδο 2 για να εγκαταστήσετε και να εκτελέσετε μια μακροεντολή.
2. Μόνο αυτήν τη φορά, αντικαταστήστε τη μακροεντολή με τα εξής:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Ανάκτηση σπασμένου εγγράφου

Στις μέρες μας, υπάρχει κάτι παραπάνω από ένας τρόπος για να ανακτήσετε τα χαμένα δεδομένα. Για παράδειγμα, η χρήση αντιγράφων ασφαλείας παραμένει πάντα η κορυφαία σας προτεραιότητα. Εάν αυτό δεν ικανοποιεί την ανάγκη σας να λάβετε πίσω τις πιο πρόσφατες πληροφορίες, μπορείτε να δοκιμάσετε ένα επισκευή εγγράφων εργαλείο.

Εισαγωγή συγγραφέα:

Η Vera Chen είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων επισκευή xlsx και pdf επισκευή προϊόντων λογισμικού. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com