2 τρόποι εκτύπωσης των λιστών εργασιών του Outlook με διαφορετικές κατηγορίες σε διαφορετικές σελίδες

Εάν έχετε εκχωρήσει διάφορες κατηγορίες χρωμάτων στις εργασίες σας στο Outlook και τώρα θέλετε να εκτυπώσετε τις λίστες εργασιών με διαφορετικές κατηγορίες σε διαφορετικές σελίδες, μπορείτε να ανατρέξετε σε αυτό το άρθρο. Εδώ θα σας κοινοποιήσουμε 2 μεθόδους για να το αποκτήσετε.

Για να ταξινομήσετε και να διαχειριστείτε καλά τις εργασίες σας, ίσως έχετε εφαρμόσει κατηγορίες χρωμάτων στις εργασίες σας. Τώρα, εάν θέλετε να εκτυπώσετε τις λίστες των εργασιών σας με διαφορετικές κατηγορίες σε διαφορετικές σελίδες, διαβάστε παρακάτω. Στα ακόλουθα, θα σας παρουσιάσουμε 2 μέσα για να το αποκτήσετε.

Μέθοδος 1: Μη αυτόματη εκτύπωση λιστών εργασιών μία προς μία

1. Πρώτα απ 'όλα, στο Outlook, αποκτήστε πρόσβαση στο παράθυρο "Εργασίες".
2. Στη συνέχεια, ανοίξτε ένα φάκελο εργασιών.
3. Στη συνέχεια, πατήστε "Ctrl + E" για να ενεργοποιήσετε την κορδέλα "Αναζήτηση".
4. Μετά από αυτό, στην καρτέλα "Αναζήτηση", κάντε κλικ στο κουμπί "Κατηγοριοποίηση".
5. Από την αναπτυσσόμενη λίστα, επιλέξτε μια κατηγορία χρωμάτων.
6. Στη συνέχεια, μόνο οι εργασίες με την επιλεγμένη κατηγορία θα παραμείνουν στη λίστα.
7. Τώρα, μεταβείτε στο "Αρχείο"> "Εκτύπωση" για να εκτυπώσετε αυτήν τη λίστα εργασιών.
8. Στη συνέχεια, με τον ίδιο τρόπο, εκτυπώστε τις λίστες εργασιών με τις άλλες κατηγορίες χρωμάτων μία προς μία χειροκίνητα.

Μέθοδος 2: Εκτύπωση μαζικής λίστας εργασιών από το VBA

1. Στην αρχή, ενεργοποιήστε τον επεξεργαστή VBA σύμφωνα με το «Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
2. Στη συνέχεια, προσθέστε την αναφορά στο "MS Excel Object Library" σύμφωνα με το "Πώς να προσθέσετε μια αναφορά βιβλιοθήκης αντικειμένων σε VBA".
3. Στη συνέχεια, αντιγράψτε τον ακόλουθο κώδικα VBA σε μια λειτουργική μονάδα.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Στη συνέχεια, πατήστε το πλήκτρο "F5" για να εκτελέσετε αυτήν τη μακροεντολή αμέσως.
5. Όταν ολοκληρωθεί η μακροεντολή, οι λίστες εργασιών με διαφορετικές κατηγορίες θα εκτυπωθούν σε διαφορετικές σελίδες, όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης.

Λάβετε πίσω πολύτιμα δεδομένα από το συμβιβασμένο αρχείο PST

Εάν υπόκειται σε μη προσβάσιμο αρχείο PST, το επόμενο βήμα σας είναι αναμφίβολα Επισκευή PST. Σε αυτήν την περίπτωση, μπορείτε πρώτα να δοκιμάσετε το εργαλείο επιδιόρθωσης εισερχομένων. Υπό την προϋπόθεση ότι αποτυγχάνει, μπορείτε να προχωρήσετε για να δοκιμάσετε ένα άλλο εξωτερικό εργαλείο, όπως DataNumen Outlook Repair. Είναι σε θέση να ανακτήσει δεδομένα PST σε γρήγορο χρόνο.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση mdf και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com