2 γρήγοροι τρόποι μαζικής εξαγωγής όλων των υπερσυνδέσμων από το έγγραφο του Word

Αυτό το άρθρο θα σας δείξει 2 γρήγορους τρόπους εξαγωγής όλων των υπερσυνδέσμων από το έγγραφο του Word, ώστε να ακολουθήσετε τους συνδέσμους.

Κάθε τόσο συχνά, μπορεί να υπάρχουν εκατοντάδες υπερσύνδεσμοι που διασκορπίζονται σε ένα έγγραφο του Word. Σε αυτό το σενάριο, εάν πρέπει να ακολουθήσετε έναν συγκεκριμένο σύνδεσμο, πρέπει να περιηγηθείτε στο έγγραφο για να το βρείτε πρώτα, κάτι που μπορεί να είναι τόσο πόνο σε ένα μακρύ αρχείο.

Ωστόσο, εάν τα εξαγάγετε σε ένα νέο έγγραφο, τα πράγματα μπορούν να γίνουν πολύ πιο εύκολα. Εδώ είναι οι λύσεις μας.

Μέθοδος 1: Χρησιμοποιήστε τη δυνατότητα "Εύρεση"

1. Αρχικά, κάντε κλικ στην καρτέλα "Αρχική σελίδα" και στη συνέχεια στο κουμπί με το βέλος κοντά στην εντολή "Εύρεση".
2. Στο αναπτυσσόμενο μενού επιλέξτε "Σύνθετη Εύρεση" για να ανοίξετε το παράθυρο διαλόγου "Εύρεση και αντικατάσταση".
3. Στη συνέχεια κάντε κλικ στο κουμπί "Περισσότερα" και κάντε κλικ στο "Μορφή".
4. Επιλέξτε "Στυλ" για να ανοίξετε το πλαίσιο "Εύρεση στυλ".
5. Επιλέξτε "Hyperlink" και κάντε κλικ στο "OK".
6. Στη συνέχεια, κάντε κλικ στο "Εύρεση σε" και επιλέξτε "Κύριο έγγραφο".

Μπορείτε να δείτε όλους τους υπερσυνδέσμους στην επιλογή τώρα. Ωστόσο, εάν τα αντιγράψετε και τα επικολλήσετε σε ένα νέο έγγραφο, θα βρείτε ότι οι σύνδεσμοι χάνουν τη μορφοποίησή τους και γίνονται απλά κείμενα.

Προς το παρόν, η Microsoft δεν διαθέτει λύση για αυτό το ζήτημα. Επομένως, πρέπει να μετατρέψετε απλά κείμενα σε υπερσυνδέσμους ξανά με μη αυτόματο τρόπο. Εδώ είναι το προηγούμενο άρθρο μας, που απαριθμεί διάφορους τρόπους που μπορείτε να ακολουθήσετε: 5 τρόποι μετατροπής κειμένων URL σε υπερσυνδέσμους στο έγγραφο του Word

Λόγω αυτού του μειονεκτήματος, σας προτείνουμε έναν άλλο τρόπο, που εκτελείται επίσης με τη βοήθεια της λειτουργίας "Εύρεση". Ανατρέξτε στην ενότητα "Εύρεση όλων των υπερσυνδέσμων σε ένα έγγραφο" σε αυτό το άρθρο: Τρόπος εύρεσης, αλλαγής και διαγραφής υπερσυνδέσμων στο έγγραφο του Word

Αφού βρείτε όλους τους υπερσυνδέσμους, κάνετε τις εργασίες "Αντιγραφή" και "Επικόλληση" για να τις εξαγάγετε.

Μέθοδος 2: Εκτέλεση κωδικών VBA

1. Πρώτα απ 'όλα, πατήστε "Alt + F11" για να ανοίξετε τον επεξεργαστή VBA.
2. Στη συνέχεια κάντε κλικ στο "Εισαγωγή" και επιλέξτε "Ενότητα" για να δημιουργήσετε ένα νέο στο έργο "Κανονικό".
3. Στη συνέχεια, κάντε διπλό κλικ στη λειτουργική μονάδα για να ανοίξετε χώρο επεξεργασίας και επικολλήστε τους παρακάτω κωδικούς:

Sub ExtractAllhyperlinksInDoc()
  Dim objDoc As Document, objNewDoc As Document
  Dim objHyperlink As Hyperlink
 
  '  Initialization
  Set objDoc = ActiveDocument
  Set objNewDoc = Documents.Add
 
  '  Copy hyperlinks and paste them to a new document.
  With objDoc
    For Each objHyperlink In .Hyperlinks
      objHyperlink.Range.Copy
      objNewDoc.Activate
      With Selection
        .Paste
        .InsertParagraph
        .Collapse Direction:=wdCollapseEnd
      End With
    Next objHyperlink
  End With
End Sub

4. Τέλος, κάντε κλικ στο κουμπί "Εκτέλεση".

Τώρα θα ανοίξει ένα νέο έγγραφο και όλοι οι υπερσύνδεσμοι μπορούν να κάνουν κλικ εκεί.

Εκτός αυτού, σε περίπτωση που χρειάζεται μια δέσμη αρχείων για επεξεργασία, μπορείτε να εκτελέσετε αυτήν τη μακροεντολή παρακάτω:

Sub ExtractHyperlinksFromMultiDoc()
  Dim objDoc As Document, objNewDoc As Document
  Dim objHyperlink As Hyperlink
  Dim strFile As String, strFolder As String
 
  '  Initialization
  Set objNewDoc = Documents.Add
  strFolder = InputBox("Enter folder path here: ", "Folder path")
  strFile = Dir(strFolder & "\" & "*.docx", vbNormal)
 
  '  Open each file in the folder to extract hyperlinks and past them to a new document.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & "\" & strFile)
 
    With objDoc
      For Each objHyperlink In .Hyperlinks
        objHyperlink.Range.Copy
        objNewDoc.Activate
        With Selection
          .Paste
          .InsertParagraph
          .Collapse Direction:=wdCollapseEnd
        End With
      Next objHyperlink
    End With
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

Θυμηθείτε να τακτοποιήσετε πρώτα όλα τα έγγραφα σε έναν φάκελο. Στη συνέχεια, εκτελέστε την παραπάνω μακροεντολή για να λάβετε ένα πλαίσιο εισαγωγής. Εισαγάγετε τη διαδρομή φακέλου και κάντε κλικ στο "OK".

Όλοι οι υπερσύνδεσμοι είναι πλέον διαθέσιμοι σε ένα νέο έγγραφο.

Έτοιμο για σφάλματα στο Word

Ανεξάρτητα από το πόσο απρόθυμοι να αντιμετωπίσουμε λάθος στο Word. Είναι αναπόφευκτο να υποφέρετε αυτό από καιρό σε καιρό. Η πρότασή μας είναι όταν το Word καταρρέει, επιλέγοντας έναν ικανό Επισκευή λέξεων εργαλείο. Απλώς αφήστε τα πάντα στον επαγγελματία.

Εισαγωγή συγγραφέα:

Η Vera Chen είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων xls ζημιά και pdf επισκευή προϊόντων λογισμικού. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com