2 Μέθοδοι μαζικής διαγραφής όλων των επαφών χωρίς διεύθυνση ηλεκτρονικού ταχυδρομείου στο Outlook

Εάν διαπιστώσετε ότι ορισμένες επαφές δεν έχουν διεύθυνση ηλεκτρονικού ταχυδρομείου στο Outlook σας, ίσως θελήσετε να επεξεργαστείτε κάθε φάκελο Επαφών για να διαγράψετε όλες αυτές τις επαφές. Αυτή η ανάρτηση θα σας δείξει 2 τρόπους.

Ίσως έχετε πολλές επαφές στο Outlook και ορισμένες από αυτές δεν έχουν διεύθυνση email. Εάν πιστεύετε ότι δεν είναι πλέον χρήσιμα, πρέπει να ελπίζετε να διαγράψετε όλες τις επαφές χωρίς διεύθυνση ηλεκτρονικού ταχυδρομείου. Με τον τυπικό τρόπο, μπορείτε να χρησιμοποιήσετε την "Άμεση αναζήτηση" για να τα βρείτε και στη συνέχεια να τα διαγράψετε χειροκίνητα, όπως η ακόλουθη Μέθοδος 1. Ωστόσο, είναι λίγο κουραστικό. Επομένως, στη Μέθοδο 2, θα σας διδάξουμε έναν άλλο πιο αποτελεσματικό τρόπο.

Μέθοδος 1: Μη αυτόματη διαγραφή μετά την εύρεση επαφών χωρίς διεύθυνση ηλεκτρονικού ταχυδρομείου

1. Για αρχή, πατήστε τα πλήκτρα "Ctrl + 3" για να αποκτήσετε πρόσβαση στο παράθυρο "Επαφές".
2. Στη συνέχεια, κάντε κλικ στο πλαίσιο αναζήτησης.
3. Στη συνέχεια, στην αναδυόμενη κορδέλα "Αναζήτηση", κάντε κλικ στην επιλογή "Όλα τα στοιχεία επικοινωνίας".
4. Στη συνέχεια, κάντε κλικ στην επιλογή "Έχει διεύθυνση"> "Έχει διεύθυνση ηλεκτρονικού ταχυδρομείου".
5. Μετά από αυτό, το κριτήριο "NOT emailaddresses: = []" θα προστεθεί στο πλαίσιο αναζήτησης. Πρέπει να αφαιρέσετε το "ΟΧΙ".
6. Στη συνέχεια, θα αναφέρονται όλες οι επαφές χωρίς διεύθυνση email.
7. Τώρα, θα πρέπει να επιλέξετε επαφές στα αποτελέσματα αναζήτησης με μη αυτόματο τρόπο, καθώς οι ομάδες επαφών σας πρέπει να βρίσκονται στη λίστα.
8. Τέλος, πατήστε το πλήκτρο "Del" για να διαγράψετε όλες τις επιλεγμένες επαφές.

Μέθοδος 2: Μαζική διαγραφή όλων των επαφών χωρίς διεύθυνση ηλεκτρονικού ταχυδρομείου με VBA

1. Αρχικά, πατήστε "Alt + F11" για να ξεκινήσετε το πρόγραμμα επεξεργασίας VBA στο Outlook.
2. Στη νέα οθόνη, αντιγράψτε τον ακόλουθο κώδικα VBA σε μια ενότητα.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Αργότερα, κάντε κλικ στην υπορουτίνα "BatchDeleteAllContactsWithoutEmailAddress".
4. Τελικά, πατήστε "F5" για να ενεργοποιήσετε αυτήν τη μακροεντολή.
5. Όταν ολοκληρωθεί, θα λάβετε ένα μήνυμα σχετικά με τα αποτελέσματα, όπως η παρακάτω εικόνα.
6. Όλες οι επαφές χωρίς διεύθυνση email έχουν μετακινηθεί στο φάκελο "Διαγραμμένα στοιχεία".

Κρατήστε μακρυά από όλους τους πιθανούς κινδύνους

Το Outlook μπορεί να καταστραφεί λόγω διαφόρων παραγόντων, όπως ιοί, σφάλματα χρήστη, αστοχίες λογισμικού καθώς και σφάλματα υλικού. Πρέπει να είστε απρόθυμοι να αντιμετωπίσετε ζημιά στο Outlook, επομένως θα πρέπει να κρατήσετε όλους αυτούς τους πιθανούς κινδύνους. Για παράδειγμα, πρέπει να προσαρτήσετε ισχυρό λογισμικό προστασίας από ιούς στον υπολογιστή σας. Επιπλέον, πρέπει να δημιουργείτε αντίγραφα ασφαλείας των δεδομένων του Outlook σε τακτική βάση. Τελευταίο αλλά όχι λιγότερο σημαντικό, καλύτερα να προετοιμάσετε ένα στιβαρό και αξιόπιστο εργαλείο επισκευής, όπως DataNumen Outlook Repair. Μπορεί να διορθώσει το δικό σας κατεστραμμένο PST αρχείο με ευκολία.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων SQL Server διαφθορά και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com