Kako brzo ukloniti duplicirane Outlook stavke u fascikli putem VBA

Ako želite ukloniti duplikate stavki u Outlooku, pretraživanje i uklanjanje jedne po jedne bit će prilično problematično. Ovaj članak će vas naučiti kako to brzo završiti pomoću Outlook VBA.

U mom prethodnom članku – “Kako brzo pronaći i ukloniti duplikate e-pošte u Outlooku“, možete naučiti trik za pronalaženje i uklanjanje duplikata e-pošte, koji prvo sortirate mejlove po temi, zatim po vremenu prijema, a zatim po privitcima kako biste saznali duplikate i na kraju odaberite duplikate i pritisnite tipku “Delete”. Iako je ova metoda naizgled malo prikladnija, ali je daleko problematičnija u odnosu na korištenje Outlook VBA. Pomoću sljedećih VBA kodova možete brzo ukloniti duple stavke jednim klikom, bez obzira na e-poštu, zadatke, kontakte ili sastanke. Sada čitajte dalje da biste dobili kodove u detalje.

Uklonite duplikate Outlookovih stavki u fascikli

1. Za početak, pokrenite Outlook program.
2. Zatim pritisnite tipke “Alt + F11”.
3. U sledećem prozoru VBA editora, dvaput kliknite da biste otvorili modul koji je u upotrebi ili direktno ubacite novi modul pomoću “Insert” > “Module”.
4. Zatim kopirajte i zalijepite sljedeće VBA kodove u modul.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Nakon toga, digitalno potpišite ovaj makro i promijenite sigurnosni nivo Outlook makroa na niski.
6. Kasnije možete pokrenuti ovaj novi VBA projekat. Direktno kliknite na ikonu “Run” na traci sa alatkama.
7. Nakon toga, od vas će se tražiti da odaberete fasciklu u koju želite da uklonite duplirane stavke.
8. Konačno, duple stavke u odabranom folderu će se odjednom izbrisati.

Zaštitite ranjive PST podatke

Zbog činjenice da je PST datoteka podložna korupciji, stoga biste trebali uložiti mnogo napora da zaštitite svoju PST datoteku. Na primjer, trebali biste spriječiti da Outlook bude nepropisno zatvoren. Nadalje, morate pripremiti robustan Outlook popravka alat, kao npr DataNumen Outlook Repair koji će moći spasiti vaš PST na vrijeme.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporavi se SQL Server i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com