Kako brzo odštampati sve slikovne priloge Outlook e-pošte samo na jednoj stranici

Da bi uštedeli mastilo i papir za štampač, neki korisnici žele da štampaju sve slike priložene u e-poruci samo na jednoj stranici, umesto jedne slike po stranici. Sada će ovaj članak podijeliti način da se to ostvari.

Kao što svi znamo, štampanje slika je prilično trošenje mastila za štampač. Stoga, da biste uštedjeli mastilo i papir za štampač, možda više volite da štampate mnogo priloga slika na istoj stranici umesto da štampate slike na odvojenim stranicama. Iako Outlook ne nudi takvu funkciju, ipak je možete postići na sljedeće načine.

Odštampajte sve slikovne priloge Outlook e-pošte samo na jednoj stranici

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim, u prozoru programa Outlook, dodirnite tipke “Alt + F11”.
3. Zatim ćete ući u prozor „Microsoft Visual Basic for Applications“ u kojem prvo morate omogućiti „Microsoft Word Object Library“.
4. Nakon toga morate otvoriti modul koji se ne koristi.
5. Nakon toga, kopirajte i zalijepite sljedeći VBA kod u ovaj modul.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Kasnije se možete vratiti na listu e-pošte. Odaberite ili otvorite e-poštu čije priloge sa slikama želite odštampati.
7. Zatim pokrenite ovaj makro. U trenutnom prozoru makroa, samo pritisnite tipku “F5” ili kliknite na ikonu “Run” na traci sa alatkama.
8. Konačno, kada makro završi s radom, svi prilozi sa slikama izvorne e-pošte bit će odštampani na jednoj stranici, kao na sljedećem snimku ekrana:

Pozabavite se oštećenim Outlook datotekama

Sa sve više i više podataka pohranjenih u vašem Outlooku, vaša Outlook datoteka postaje sve ranjivija. Može biti ugrožena zbog različitih unutrašnjih i vanjskih faktora. Takođe, teško je predvidjeti korupciju Outlooka. Dakle, ono što možete učiniti je da osigurate trenutno i efikasno spašavanje kada se suočite s oštećenjem Outlooka. Na primjer, morate zadržati specijalistu PST repair alat, kao DataNumen Outlook Repair u blizini. On će skenirati i vratiti oštećene datoteke kao povjetarac.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporavi se Sql Server i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com