Kako brzo pronaći pasuse od jedne rečenice u Word dokumentu

U ovom postu želimo vam pokazati brz način za pronalaženje svih paragrafa od jedne rečenice u vašem Word dokumentu putem VBA.

S vremena na vrijeme, neki dokumenti mogu imati vrlo specifične zahtjeve za njihovo formatiranje i strukturu. Na primjer, možda vam neće biti dozvoljeno da imate pasuse sa samo jednom rečenicom. Ove paragrafe nije teško prepoznati, ali je potrebno vrijeme, pogotovo što je dokument dugačak.

Danas ćemo vam ponuditi brz način da navedete sve paragrafe od jedne rečenice u vašem dokumentu.

Pronađite sve paragrafe od jedne rečenice u jednom dokumentu

1. Prvo, Word broji tačku kao rečenicu. Dakle, ako postoje riječi kao što su "g." ili "gospođa", Word to smatra rečenicom. Da biste isključili takvo ometanje, trebate zamijeniti "g." sa “Mr”. A kada završite sa pronalaženjem paragrafa jedne rečenice, možete ih vratiti nazad. Za zamjenu riječi možete pogledati ovaj link: Kako pronaći i zamijeniti više stavki u Word dokumentu
2. Drugo, pritisnite “Alt+ F11” da pokrenete VBA editor.
3. Zatim kliknite na "Normalni" projekat.
4. Kliknite karticu "Insert" na traci menija i odaberite "Module" na njegovom padajućem meniju.
5. Zatim dvaput kliknite na modul da biste ga otvorili.
6. Zalijepite sljedeće kodove na modul:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Na kraju, ali ne i najmanje važno, kliknite na dugme “Run” ili pritisnite “F5”.

Primit ćete takvu poruku u kojoj će vam biti rečeno da je posao obavljen.

Pronađite sve paragrafe od jedne rečenice u više dokumenata

1. Za početak, morate sve ciljne dokumente staviti u mapu.
2. Zatim instalirajte i pokrenite sljedeći makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. U prozoru "Pretraži" koji se otvori, izaberite fasciklu u kojoj čuvate dokumente i kliknite na "OK".

Makro će tada istaknuti sve paragrafe od jedne rečenice i ostaviti dokumente otvorenim. Ako dokument ne sadrži paragraf od jedne rečenice, biće zatvoren. Osim toga, postoji okvir za poruku, koji označava broj pasusa od jedne rečenice u svakom dokumentu.

Pozabavite se incidentom gubitka podataka

Korisničke greške i iznenadni nestanak struje mogu dovesti do nestanka Worda. Dok srušena Word ne samo da može uticati na svakodnevni rad, već i dovesti do doc oštećenjaOvo nipošto nije najiritantniji dio katastrofe s podacima. Bolje je odmah angažovati program za popravak kako biste oporavili podatke.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti excel i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com