Kako brzo izvesti statistiku glasanja iz Outlook e-pošte u Excel radni list

Ako ste poslali e-poruku sa dugmadima za glasanje, nakon što vam primaoci pošalju svoje odgovore, možda ćete želeti da prebrojite i izvezete statistiku glasanja u Excel radni list. Dakle, u ovoj strost, mi ćemo vas naučiti kako to brzo postići.

Outlook je toliko moćan da čak nudi i funkciju „glasanja“. Moj prethodni članak “Vješto korištenje MS Outlook-a za glasanje” je naučio kako ga efikasno koristiti. Također, most vremena, nakon glasanja, možete nastaviti sa izvozom statistike glasanja u Excel radni list iz nekih razloga, kao što je želja da odštampate statistiku. Ali Outlook to ne podržava prema zadanim postavkama. Stoga ćemo vas u nastavku naučiti kako da ovo realizujete kao čep.

Izvezite statistiku glasanja u e-poruci u Excel radni list

1. Na samom početku pokrenite svoju Outlook aplikaciju.
2. Zatim biste trebali pritisnuti tipke “Alt + F11” u glavnom prozoru programa Outlook.
3. Zatim u prozoru “Microsoft Visual Basic za aplikacije” treba da omogućite “Microsoft Excel Object Library”. Kliknite na “Alati” > “Referenca”. Zatim u iskačućem dijaloškom okviru označite potvrdni okvir ispred „Microsoft Excel Object Library” i na kraju pritisnite “OK”.
4. Nakon toga možete umetnuti novi modul ili otvoriti onaj koji nije u upotrebi.
5. Nakon toga, kopirajte i zalijepite sljedeće VBA kodove u ovaj modul.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Nakon toga, radi lakšeg pristupa, bolje je da dodate novi makro na alatnu traku za brzi pristup.
6. Na kraju, možete probati.

• Prvo odaberite izvornu e-poštu koja sadrži dugmad za glasanje.
• Zatim kliknite na dugme makro na traci sa alatkama za brzi pristup.
• Nakon što se ovaj makro završi, možete pretražiti unaprijed definiranu lokalnu mapu u kojoj ćete vidjeti novu Excel radnu knjigu.
• Otvorite ovu Excel radnu svesku. Sada ćete vidjeti statistiku glasanja, prikazanu na slici ispod:

Niko ne može u potpunosti da spreči greške u programu Outlook

Iako Outlook dolazi sa raznim mogućnostima, ne postoji takva funkcija koja bi nam pomogla da izbjegnemo Outlook greške. Sve vrste faktora mogu uzrokovati Outlook greške. Na primjer, ako često neispravno izlazite iz Outlooka, vjerovatno ćete patiti PST korupcija. U takvom scenariju, nemate izbora osim da koristite neke moćne alate za spašavanje vaše PST datoteke, npr DataNumen Outlook Repair. Zaslužio je mnogo pohvala zbog svoje visoke stope oporavka.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući corrupt mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com