Kako brzo izvesti podatke o veličini svih fascikli u PST datoteci u Excel datoteku

Ako želite provjeriti informacije o veličini svake mape u PST datoteci, možete koristiti metodu izloženu u ovom članku. Brzo će izvesti informacije o veličini svih foldera u PST datoteci u Excel datoteku.

Kada je vaša PST datoteka prevelika, možda ćete htjeti provjeriti veličinu svake mape. To će vam pomoći da lako shvatite koji su veći i napravite odgovarajuće arhiviranje na osnovu veličine. Općenito, da biste provjerili veličinu fascikle, možete jednostavno kliknuti desnim tasterom miša na fasciklu i zatim izabrati „Svojstva“. U novom iskačućem dijaloškom okviru možete kliknuti na dugme „Veličina fascikle“. Međutim, ako ste kreirali mnogo fascikli, ručna provjera informacija o veličini jedne po jedne je prilično problematična. Dakle, ako želite da skupni dobijete informacije o veličini svih fascikli u PST datoteci, možete koristiti sledeći VBA kod. Izveziće sve nazive fascikli i informacije o veličini u Excel datoteku u jednom potezu.

Izvezite informacije o veličini svih fascikli u PST datoteci u Excel datoteku

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim se prebacite na karticu „Developer“ i kliknite na dugme „Visual Basic“ ili pritisnite tastere „Alt + F11“ da biste pristupili VBA editoru.
3. Zatim u prozoru „Microsoft Visual Basic za aplikacije“ otvorite modul koji nije u upotrebi.
4. Nakon toga, kopirajte i zalijepite sljedeće VBA kodove u ovaj modul.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Nakon toga, trebali biste postaviti nivo sigurnosti makroa Outlook na niski.
6. Na kraju, možete probati.

• Pritisnite taster F5 u trenutnom prozoru makroa.
• Zatim će se od vas tražiti da odaberete PST datoteku, kao na sljedećoj slici:
• Nakon odabira izvorne datoteke, Outlook će početi izvoziti informacije o veličini u Excel.
• Nakon što se makro završi, dobićete poruku kao na slici ispod.
• Na kraju, moći ćete pronaći Excel datoteku u unaprijed definiranoj lokalnoj mapi. Excel datoteka će izgledati ovako:

Pozabavite se čestim PST greškama

Budući da je Outlook sklon greškama, možda ste ikada imali mnogo problema u svom Outlooku. Kako biste se bolje i fleksibilnije nosili sa frustrirajućim PST problemima, preporučljivo je da u blizini držite iskusan i renomiran uslužni program za popravke, kao što je npr. DataNumen Outlook Repair. To je u stanju popraviti PST problemi kao povjetarac.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući SQL Server oporavak i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com