Kako brzo izvesti sve Outlook fascikle i stavke u odjeljku "Favoriti" u Windows folder

Ako želite da izvezete sve Outlook fascikle kao i njegove stavke u odeljku „Favoriti“, možete pogledati ovaj članak. Ovdje ćemo vam pokazati kako da to postignete u kratkom vremenu.

Generalno, fascikle i njihove stavke u sekciji „Favoriti“ su od velike važnosti i često su potrebne. Stoga ćete ih ponekad možda željeti izvesti na lokalni disk. Na standardni način, morate kreirati Windows fascikle prema fasciklama u „Favoritima“ i sačuvati stavke kao MSG datoteke jednu po jednu na lokalnom disku. To je previše zamorno. Dakle, ovdje ćemo izložiti daleko efikasniji način. Sada čitajte dalje da biste je dobili.

Izvezite sve fascikle i stavke u odjeljku „Favoriti“ u Windows folder

1. Za početak, pristupite VBA uređivaču u Outlooku pozivajući se na “Kako pokrenuti VBA kod u vašem Outlooku".
2. Zatim kopirajte sljedeći kod u prazan modul.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Zatim kliknite na ikonu „Pokreni“ na traci sa alatkama.
4. Zatim, u iskačućem dijaloškom okviru, odaberite odredišnu Windows fasciklu i kliknite na “OK”.
5. Kada se makro završi, prikazat će se Windows folder.
6. U ovoj Windows fascikli, fascikle i njegove stavke u odeljku „Favoriti“ su izvezene, kao na sledećem snimku ekrana.

Vratite Outlook podatke iz rezervnih kopija

Preporučuje se da redovno pravite rezervne kopije Outlook datoteka. To je zato što ako trpite oštećenje Outlook datoteke, možete oporaviti Outlook podaci iz rezervnih kopija lako. Ali, ako nemate takvu sigurnosnu kopiju, morate pokušati naporno popraviti Outlook. U to vrijeme alat za popravku inboxa neće biti od velike pomoći. Morate uzeti pomoć za popravak vanjskog alata, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen sql i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com