Kako brzo izvesti sve hiperveze u više Outlook e-poruka u Excel

Kada trebate izdvojiti sve hiperlinkove iz jedne ili više e-poruka, glupo je kopirati ih jednu po jednu. Ovaj članak će vas naučiti metodi za brzo izvoz svih hiperlinkova iz više e-poruka u Excel.

Iz nekih razloga, kao što je evidentiranje hiperveza u svim vašim poslanim e-porukama, morat ćete izdvojiti hiperveze. Bez ikakve sumnje, nije preporučljivo da ih izvlačite i kopirate ručno. Morate čeznuti za mnogo pametnijim pristupom, kao što je korištenje VBA. Ovdje ćemo vam podijeliti takav komad VBA koda, koji može izvesti sve hiperveze u mnogim e-porukama u Excel jednostavnim klikom.

Izvezite sve hiperveze u više e-poruka u Excel

1. Za početak, pokrenite Outlook program kao i obično.
2. Zatim, u prozoru programa Outlook, trebate pritisnuti tipke “Alt + F11”.
3. Odmah ćete dobiti pristup Outlook VBA editoru.
4. Nakon toga, potrebno je da omogućite "Microsoft Word Object Library" kao i "Microsoft Excel Object Library". Kliknite na "Alati" > "Reference" i zatim ih omogućite u skočnom dijaloškom okviru.
5. Zatim morate otvoriti neiskorišteni modul, u kojem morate kopirati VBA kod ispod u ovaj modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Nakon toga, možete izaći iz trenutnog prozora VBA editora.
7. Kasnije pristupite "Opcijama Outlook" da biste prilagodili traku sa alatkama za brzi pristup i dodali novododati makro na traku sa alatkama za brzi pristup.
8. Konačno možete snimiti:

• Prvo, na listi e-pošte izaberite e-poruke čije hiperveze želite da izdvojite.
• Zatim kliknite na dugme makro na traci sa alatkama za brzi pristup.
• Kada se makro završi, dobićete Excel fajl, kao na slici ispod:

Popravite neočekivane probleme sa Outlookom

Problemi s Outlookom mogu se povremeno javljati bez ikakvih znakova. Ali, u slučaju manjih grešaka, Outlook se može oporaviti jednostavnim ponovnim pokretanjem ili... alat za popravku inboxa. Ali ako naiđete na neke ozbiljne probleme, unutrašnja sredstva neće imati efekta. U ovom trenutku, vaše posljednje sredstvo je definitivno renomiraniji i robusniji alat, kao što je npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com