Kako brzo izvesti broj stavki u svakoj kategoriji boja u Outlooku u Excel

Ako želite brzo dobiti ukupan broj stavki u svakoj kategoriji boja u vašoj Outlook PST datoteci, možete koristiti VBA kod izložen u ovom članku. Izveziće sve brojeve u Excel datoteku direktno za vašu zgodnu provjeru.

Ponekad, iz nekih razloga, možda ćete želeti da izbrojite koliko je stavki u svakoj kategoriji boja u datoteci podataka programa Outlook. Općenito, možete koristiti trenutnu pretragu za brojanje. Na primjer, prvo kliknite na polje za pretragu. Zatim kliknite na dugme „Kategorizuj“ na traci „Traži“ i sa padajuće liste odaberite određenu kategoriju boja. Zatim odaberite "Sve Outlook stavke" u grupi trake "Opseg". Kasnije, nakon završetka pretraživanja, sve stavke u odabranoj kategoriji boja će biti izlistane. Sada možete vidjeti broj ovih rezultata pretraživanja u donjem lijevom kutu statusne trake.

Bez ikakve sumnje, ako imate puno kategorija boja, na taj način će brojanje jedne po jedne biti vrlo zamorno. Stoga, kao odgovor na ovaj zahtjev, ovdje ćemo otkriti vrlo brzu metodu. On će direktno izvesti sve brojeve u Excel datoteku.

Izvezite broj stavki u svakoj kategoriji boja u Outlooku u Excel

1. Prvo, pokrenite Outlook aplikaciju.
2. Zatim pritisnite tipke “Alt + F11” za pristup Outlook VBA editoru.
3. U sledećem prozoru „Microsoft Visual Basic za aplikacije“ otvorite prazan modul.
4. Zatim možete kopirati sljedeće VBA kodove u ovaj prozor modula.

Public objDictionary As Object
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet
 
Sub ExportCountofItemsinEachColorCategories()
    Dim objCategories As Object
    Dim objCategory As Object
    Dim objPSTFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
    Dim strExcelFile As String
 
    'Create a New Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Color Category"
    objExcelWorksheet.Cells(1, 2) = "Count"
 
    'Find all the color categories
    Set objDictionary = CreateObject("Scripting.Dictionary")

    Set objCategories = Outlook.Application.Session.Categories
    For Each objCategory In objCategories
        objDictionary.Add objCategory.Name, 0
    Next
 
    Set objPSTFile = Outlook.Application.Session.PickFolder
 
    For Each objFolder In objPSTFile.Folders
        ProcessFolder objFolder
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Outlook\Color Categories (" & Format(Now, "yyyy-mm-dd_hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub
 
Private Sub ProcessFolder(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubFolder As Object
    Dim ArrayCategories As Variant
    Dim VarCategory As Variant
    Dim ArrayKey As Variant
    Dim ArrayItem As Variant
    Dim i As Long
    Dim nRow As Integer

    'Count the items in each color category via Dictionary object
    For Each objItem In objCurrentFolder.Items
        If objItem.Categories <> "" Then
           ArrayCategories = Split(objItem.Categories, ",")
           For Each VarCategory In ArrayCategories
               If objDictionary.Exists(VarCategory) = True Then
                  objDictionary.Item(VarCategory) = objDictionary.Item(VarCategory) + 1
               End If
          Next
        End If
    Next
 
    ArrayKey = objDictionary.Keys
    ArrayItem = objDictionary.Items
    nRow = 2
 
    'Input the information into the new Excel file
    For i = LBound(ArrayKey) To UBound(ArrayKey)
        objExcelWorksheet.Cells(nRow, 1) = ArrayKey(i)
        objExcelWorksheet.Cells(nRow, 2) = ArrayItem(i) & “ Items”
        nRow = nRow + 1
    Next
 
    'Process the subfolders recursively
    For Each objSubFolder In objCurrentFolder.Folders
        ProcessFolder objSubFolder
    Next
End Sub

5. Nakon toga provjerite da li Outlook dozvoljava makronaredbe.
6. Konačno možete probati.

• Prvo pritisnite dugme F5 u ovom novom makrou.
• Zatim morate odabrati izvornu PST datoteku i pritisnuti “OK”.
• Kada dobijete poruku sa upitom „Završeno“, možete otići na lokalni disk i otvoriti unaprijed definiranu mapu za spremanje Excel datoteke.
• Pronađite i otvorite Excel datoteku. Izgledat će kao na sljedećoj slici:

Šta učiniti ako se Outlook iznenada sruši

Iako Outlook dolazi s više moćnih funkcija, s vremenom ćete se susresti s raznim problemima u svom Outlooku. Na primjer, Outlook se s vremena na vrijeme može srušiti. U najboljem slučaju, ponovno pokretanje Outlooka će moći riješiti problem. U najgorem slučaju, to može direktno dovesti do oštećenja PST podataka. U tom slučaju ćete koristiti različita sredstva za... popraviti PST datoteku da biste vratili maksimalan broj Outlook podataka, za koje se možete vratiti na iskusan alat kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql repair i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com