Kako brzo pretvoriti sve ugrađene slike u priloge u vašoj Outlook e-pošti

Ako želite brzo promijeniti sve slike ugrađene u tijelo poruke u priloge e-pošte, ne morate ručno uklanjati i ponovo prilagati. Možete koristiti samo dio VBA koda izložen u ovom članku.

Ponekad ćete možda poželjeti grupno pretvoriti sve ugrađene slike u priloge. Na primjer, previše slika u tijelu poruke će prekinuti vaše čitanje tekstova u tijelu. Stoga ih želite ukloniti iz tijela e-pošte i umjesto toga ih dodati kao priloge. Naravno, ovo možete učiniti ručno. Ali mora biti zgodnije ako bilo koji alat ili VBA kodovi to mogu dobiti u jednom potezu. Ovdje ćemo vam predstaviti takav VBA kod.

Brzo pretvorite sve ugrađene slike u priloge

1. Prvo, pokrenite Outlook program.
2. Zatim se možete prebaciti na karticu "Developer" i pritisnuti dugme "Visual Basic".
3. Zatim ćete ući u Outlook VBA editor prozor.
4. Nakon toga, morate kopirati sljedeći VBA kod u prazan modul.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Nakon toga, trebali biste potvrditi da je vaš Outlook podešen da dozvoljava makronaredbe.
6. Opciono, ako vam je ovo često potrebno, bolje je da dodate novi makro na traku sa alatkama za brzi pristup radi buduće zgodne provere.
7. Na kraju možete probati. Odaberite ili otvorite e-poštu, a zatim pokrenite makro klikom na dugme za novi makro na traci sa alatkama za brzi pristup.
8. Odmah će sve ugrađene slike biti promijenjene u priloge kao na sljedećem snimku ekrana:

Trikovi za zaštitu vaših vrijednih Outlook podataka

Kao što svi znamo, Outlook PST datoteka je jednako ranjiva kao i uobičajene datoteke, kao što su Word dokumenti ili Excel tabele. Stoga biste trebali i dalje paziti na sve rizike oko vaše PST datoteke, poput virusa ili nepravilnog rukovanja. Dakle, morate redovno praviti rezervne kopije podataka za vašu PST datoteku. Također, ako si to možete priuštiti, mudro je zadržati robustan Outlook popravak alat pri ruci, kao DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com