Kako brzo priložiti određene stranice Word dokumenta u Outlook e-poštu

MS Word ima direktnu funkciju koja podržava korisnike da pošalju trenutni Word dokument kao prilog e-pošte. Ali ponekad se možete nadati samo da ćete priložiti određene stranice Word dokumenta u Outlook e-poštu. Sada će vam ovaj članak podijeliti metodu.

Da biste poslali cijeli Word dokument kao prilog e-pošte u MS Word aplikaciji, možete jednostavno otići u meni „Datoteka“ i prebaciti se na karticu „Sačuvaj i pošalji“, ispod koje se nalazi dugme „Pošalji kao prilog“. Ipak, ponekad ono što želite da pošaljete mogu biti samo određene stranice dokumenta. U ovoj situaciji možete koristiti metodu predstavljenu u nastavku da biste to postigli.

Priložite određene stranice Word dokumenta u e-poštu

1. Prvo, trebali biste otvoriti izvorni Word dokument čije specifične stranice želite poslati e-poštom.
2. Zatim, nakon što uđete u prozor MS Worda, trebate pritisnuti tipke “Alt + F11”.
3. Zatim ćete dobiti pristup VBA editoru u MS Wordu.
4. Nakon toga, morate omogućiti "Microsoft Outlook Object Library". Možete kliknuti na "Alati" > "Referenca" da biste to postigli.
5. Nakon toga, trebali biste kopirati sljedeći VBA kod u modul koji nije u upotrebi.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Konačno, možete pokrenuti ovaj makro. Samo pritisnite dugme F5 ili dodirnite ikonu „Run“ na traci sa alatkama.
7. Nakon što makronaredba završi, prikazat će se nova Outlook e-pošta, koja je priložena s izvodom izvornog Word dokumenta, kao što je sljedeći snimak ekrana:

Izvucite maksimalan broj podataka iz korumpirane Outlook datoteke

Ako ste Outlook koristili decenijama, možda ste se suočili sa raznim problemima u programu Outlook, uključujući iskačuće unutrašnje poruke o grešci, iznenadna rušenja kao i ozbiljna oštećenja datoteka. Zbog činjenice da je scanpst, ugrađeni alat za popravak, može se nositi samo s malim problemima, bolje je da pri ruci držite vanjski moćni alat za popravak, recimo DataNumen Outlook Repair. Može izvući maksimum podataka iz oštećene Outlook datoteke sa podacima.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql fix i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com