Kako brzo izdvojiti sve primaoce iz više datoteka Outlook poruka (.msg).

Neki korisnici bi željeli brzo izdvojiti sve primaoce iz više datoteka Outlook poruka sačuvanih iz Outlook e-pošte. Sada, ova strost pogledat će ovo kako bismo podijelili brzi pristup.

Da biste izdvojili primaoce iz jedne datoteke Outlook poruke, možete samo dvaput kliknuti da biste je otvorili, a zatim kopirajte primaoce u otvorenom prozoru poruke. Ali, ako treba da se bavite serijom Outlook datoteka poruka, ručna metoda nije dovoljno efikasna. Stoga možete tražiti mnogo efikasniji način. Ovdje ćemo vam predstaviti jednu takvu. Čitajte dalje da biste saznali njegove detalje.

Izdvojite sve primaoce iz više datoteka Outlook poruka (.msg).

1. Za astart, dobijte pristup Outlook VBA editoru prema “Kako pokrenuti VBA kod u vašem Outlooku".
2. Zatim kopirajte i zalijepite sljedeći VBA kod u prazan modul.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Zatim pomerite kursor u prvom potprogramu.
4. Zatim kliknite na dugme “Run” ili pritisnite taster “F5”.
5. Zatim, u iskačućem dijaloškom okviru, odaberite Windows folder koji sadrži izvorne datoteke Outlook poruke (.msg).
6. Nakon odabira, kliknite na “OK” kako biste pustili makroa da nastavi s radom.
7. Kada se makro završi, pojavit će se poruka u kojoj su navedene adrese e-pošte svih ekstrahovanih primatelja, kao što je prikazano na sljedećem snimku ekrana.

Zaštitite svoje Outlook podatke od opasnosti

Outlook podaci su doduše skloni korupciji. Stoga je prilično težak zadatak zaštititi Outlook podatke. Zahtijeva da ustrajete u pravljenju redovnih rezervnih kopija Outlookovih podataka. Također, ako je moguće, razumno je i preporučljivo pripremiti iskusan i profesionalan Outlook PST repair alat, kao DataNumen Outlook Repair, tako da možete dobiti trenutnu i pravovremenu pomoć u slučaju oštećenja Outlooka.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporavi se Sql Server i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com