Kako automatski označiti sastanke za vikend kao privatne u Outlooku

Outlook rješenja Septembar 29, 2025

Za most korisnika, termini zakazani vikendom su obično privatni. Stoga žele da Outlook automatski označi i prikaže takve sastanke kao privatne. U ovom članku ćemo to ostvariti uz malo skriptiranja.

Kako bi lakše razlikovali poslovne i privatne sastanke, Outlook dozvoljava korisnicima da označe sastanke kao privatne. Na ovaj način ćete smatrati da je prilično zgodno i lako štampati kalendar bez privatnih sastanaka. U ovoj situaciji, možda ćete poželjeti da vaš Outlook automatski prepoznaje i označava određene sastanke kao privatne. Na primjer, općenito, termini vikendom su privatni, pa želite da dozvolite Outlooku da ih automatski označi kao privatne. Nakon toga, mi ćemo vas voditi da to postignete.

Auto označi termine za vikend kao privatne

Prvo pokrenite Outlook VBA editor prema “Kako pokrenuti VBA kod u vašem Outlooku".
Zatim, u prozoru „Microsoft Visual Basic za aplikacije“, stavite sledeći kod u projekat „ThisOutlookSession“.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

Nakon toga, reztart Outlook da aktivirate makro.
Od sada, svaki put kada kreirate novi sastanak ili promijenite postojeći termin za vikend, Outlook će ga automatski označiti kao privatan.

Riješite dosadne probleme s Outlookom

Moguće je da ste naišli na neke probleme pri radu sa Outlookom, kao što su neočekivano zamrzavanje aplikacija, iskačuće poruke o grešci i tako dalje. Kada ih trpite, bili biste zabrinuti. Molim te, smiri se! Panika neće pomoći ništa, ali samo pogoršava slučaj. Na prvom mjestu, možete provjeriti možete li pristupiti PST datoteci kao i obično. Ako je tako, morate popraviti PST datoteku, što se može postići putem alat za popravku inboxa ili moćniji vanjski alat, npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući mdf repair i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com