Kako grupno provjeriti sve hiperveze u vašem Word dokumentu putem VBA

U ovom članku ćemo vam pokazati automatski način za brzu grupnu provjeru valjanosti svih hiperveza u vašem Word dokumentu putem VBA.

Word dokument može sadržavati mnogo hiperveza, čak stotine. Među njima, neki su nevažeći linkovi koji vas ne vode na ispravnu web stranicu. Stoga želimo da vam ponudimo način da brzo proverite sve veze u dokumentu putem VBA.

Instalirajte i sačuvajte Word makro

1. Prije svega, otvorite VBA editor sa “Alt+ F11”.
2. Zatim kliknite na "Normalni" projekat.
3. Zatim kliknite na karticu "Insert" u meniju trake sa alatkama.
4. I izaberite “Module” na meniju.
5. Dvaput kliknite na modul da otvorite prostor za uređivanje i tamo zalijepite sljedeće kodove:

Function CheckURL(strURL As String) As Boolean
  Dim objDemand As Object
  Dim varResult As Variant
 
  On Error GoTo ErrorHandler
  Set objDemand = CreateObject("WinHttp.WinHttpRequest.5.1")
 
  With objDemand
    .Open "GET", strURL, False
    .Send
    varResult = .StatusText
  End With
 
  Set objDemand = Nothing
 
  If varResult = "OK" Then
    CheckURL = True
  Else
    CheckURL = False
  End If
 
ErrorHandler:
End Function

Sub ReturnURLCheck()
  Dim objLink As Hyperlink
  Dim strLinkText As String
  Dim strLinkAddress As String
  Dim strResult As String
  Dim nInvalidLink As Integer, nTotalLinks As Integer
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
 
  Set objDoc = ActiveDocument
  nTotalLinks = objDoc.Hyperlinks.Count
  nInvalidLink = 0
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkText = objLink.Range.Text
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        nInvalidLink = nInvalidLink + 1
        strResult = frmCheckURLs.txtShowResult.Text
        frmCheckURLs.txtShowResult.Text = strResult & nInvalidLink & ". Invalid Link Information:" & vbNewLine & _
                                          "Displayed Text: " & strLinkText & vbNewLine & _
                                           "Address: " & strLinkAddress & vbNewLine & vbNewLine
      End If
    Next objLink
 
    frmCheckURLs.txtTotalLinks.Text = nTotalLinks 
    frmCheckURLs.txtNumberOfInvalidLinks.Text = nInvalidLink
    frmCheckURLs.Show Modal
 
  End With
  Application.ScreenUpdating = True
End Sub

Sub HighlightInvalidLinks()
  Dim objLink As Hyperlink
  Dim strLinkAddress As String
  Dim strResult As String
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        objLink.Range.HighlightColorIndex = wdYellow
      End If
    Next objLink
  End With
End Sub

6. Zatim kliknite na “Sačuvaj”.
7. Zatim dodelite dugme za makro. Za detaljnije informacije možete pogledati sljedeći članak:

Kako ukloniti formatiranje zalijepljenih tekstova pomoću makroa i VBA u Wordu

Kreirajte korisnički obrazac

Uz korisnički obrazac možete jasno vidjeti ukupan broj linkova u trenutnom dokumentu, broj nevažećih veza i više detalja.

1. Prvo, ponovo kliknite na “Insert” na traci sa alatkama. Ali ovaj put odaberite “UserForm”.
2. Zatim pritisnite “F4” da otvorite “Prozor sa svojstvima” u donjem lijevom uglu. Veličina prozora je podesiva.
3. Sada nazovite korisnički obrazac kao “frmCheckURLs”.
4. Postavite naslov kao "Provjeri URL-ove".
5. Zatim pravilno postavite font.
6. Zatim kliknite na dugme "Toolbox" na traci sa alatkama.
7. Sada kliknite na “Label” na alatnoj kutiji. Koristite miša da prevučete pravougaonu oznaku na korisničkom obrascu.
8. Kliknite na oznaku da aktivirate prozor sa svojstvima. Postavite naziv oznake kao “lblInvalidURLs”, a naslov oznake kao “Invalid URLs:”.
9. Zatim odaberite odgovarajući font i prednju boju za tekst naslova naljepnice.
10. Odaberite “Text Box” na alatnoj kutiji i umetnite okvir za tekst u korisnički obrazac. Podesite njegovu veličinu.
11. Zatim postavite naziv okvira za tekst kao “txtShowResult”.
12. Postavite font i prednju boju po želji.
13. Pronađite “MultiLine” i postavite ga “True”.
14. Pronađite "Scrollbars" i odaberite okomitu traku.
15. Zatim kreirajte još dvije oznake i okvire za tekst.
16. Zatim nazovite prvu oznaku kao “lblTotalLinks” i postavite naslov kao “Ukupno veza u ovom dokumentu”.
17. I nazovite drugu oznaku kao “lblNumberOfInvalidLinks” i postavite naslov kao “Broj nevažećih veza”.
18. Imenujte prvi tekstualni okvir kao “txtTotalLinks”, a drugi kao “txtNumberOfInvalidLinks”.
19. Zatim pronađite kontrolu komandnog dugmeta na alatnoj kutiji. Napravite dva komandna dugmeta, kao što je dole:
20. Imenujte prvo dugme kao “cmdbtnClose”, a njegov tekst kao “Close”.
21. Imenujte drugo dugme kao “btnCloseAndHighlightInvalidURLs”, a njegov tekst naslova kao “Close & Highlight Invalid URLs”.
22. Zatim dvaput kliknite na dugme “Zatvori” i dugme “Zatvori i označi nevažeće URL-ove”. Unesite kodove na sljedeći način:

Pokrenite makro

Kliknite na dugme koje dodelite makrou. Evo konačnog efekta:

Možete vidjeti detaljne informacije o svakom neuspjelom linku u lijevom velikom tekstualnom okviru. I možete odabrati da zatvorite korisnički obrazac direktno ili da ga zatvorite uz isticanje svih prekinutih veza u dokumentu.

Pažljivo rješavajte probleme sa Wordom

Word je lako podložan greškama. Stoga postaje izuzetno važno da popravi Word ispravno. Most u to vrijeme, ugrađeni alat vam ne može toliko pomoći. Stoga je vaš najbolji izbor nabaviti alat za popravku treće strane.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popraviti xlsx i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com