Kako automatski postaviti Outlook na mreži ili van mreže na osnovu vašeg radnog vremena

Neki korisnici bi željeli natjerati Outlook da automatski prelazi između online i offline statusa na osnovu radnog vremena. Dakle, u ovom članku ćemo s vama podijeliti brzu metodu.

Zapravo, postavljanje Outlooka na mreži ili van mreže je vrlo jednostavno. Da biste Outlook pretvorili u status van mreže, jednostavno se možete prebaciti na karticu „Pošalji/primi“ i pritisnuti dugme „Radi van mreže“. A da biste se vratili na status na mreži, jednostavno ponovo pritisnite ovo dugme. Međutim, neki korisnici se nadaju da se Outlook može automatski prebaciti u offline status kada je van radnog vremena i vratiti se na internet za vrijeme radnog vremena. Iako Outlook ne pruža takvu funkciju, još uvijek možete koristiti sljedeći VBA kod da biste to postigli.

Automatski postavite Outlook na mreži ili van mreže na osnovu vašeg radnog vremena

1. Na samom početku pokrenite Outlook aplikaciju.
2. Zatim, nakon što dobijete pristup vašem Outlooku, trebali biste otvoriti fasciklu Zadaci.
3. Zatim biste trebali kreirati svakodnevno ponavljajuću stavku Zadatka.

• Kliknite na dugme "Novi zadatak" na traci.
• Zatim unesite “Offline” u liniju predmeta zadatka.
• Zatim kliknite na dugme "Ponavljanje" na kartici "Zadatak".
• U iskačućem dijaloškom okviru odaberite obrazac ponavljanja „Dnevno“, omogućite „Bez datuma završetka“ i pritisnite „OK“.
• Zatim biste trebali omogućiti podsjetnik u “5:00”.
• Na kraju pritisnite dugme "Sačuvaj i zatvori".

4. Nakon toga, morate kreirati još jedan zadatak koji se svakodnevno ponavlja pod nazivom “Online” i omogućiti podsjetnik u “8:00 AM”, prikazan na slici ispod:
5. Nakon toga, u glavnom prozoru programa Outlook, pritisnite tipke “Alt + F11”.
6. Zatim ćete dobiti pristup Outlook VBA editoru, u kojem trebate pronaći i otvoriti projekt “ThisOutlookSession”.
7. Kasnije kopirajte sljedeći VBA kod u ovaj projekat.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Na kraju možete ponovo pokrenuti Outlook da biste aktivirali ovaj makro.
9. Od sada, vaš Outlook će biti na mreži tokom radnog vremena i automatski će se prebaciti u status van mreže van radnog vremena.

Vaše posljednje rješenje u slučaju pada programa Outlook

Iako se Outlook može pohvaliti višestrukim funkcijama, Outlook se još uvijek ne može zaštititi od grešaka i oštećenja. Ali nemojte paničariti. Sve dok poduzimate dovoljne mjere opreza, i dalje možete efikasno zaštititi svoje Outlook podatke. Na primjer, trebali biste redovno praviti rezervne kopije svojih PST datoteka jer će vam rezervne kopije omogućiti da se vratite nazad corrupt PST podaci. Također, čuvanje moćnog alata za popravku, npr DataNumen Outlook Repair, takođe je stvar neophodnosti.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popraviti mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com