Kako automatski postaviti različito vrijeme podsjetnika za Outlook sastanke u različitim kategorijama boja

Ako Outlook sastanke klasifikujete prema kategorijama boja i želite da postavite različito vreme podsetnika za sastanke u različitim kategorijama boja, možete pogledati ovaj članak. Ovdje ćemo vas naučiti da to ostvarite pomoću Outlook VBA.

Na primjer, dijelite sastanke u dvije grupe. Jedna je u kategoriji boja "Izvan lokacije" jer je lokacija sastanka previše udaljena, a druga je u kategoriji boja "Na licu mjesta" jer je lokacija upravo ovdje. Sada želite da Outlook može automatski postaviti vrijeme podsjetnika za sastanak "Izvan lokacije" kao 1 sat prije početka, a za sastanak "Na licu mjesta" kao 15 minuta prije početka. Uzimajući u obzir ovaj zahtjev, u nastavku ćemo podijeliti brzu metodu.

Automatsko postavljanje različitih podsjetnika za sastanke u različitim kategorijama boja

1. Za početak pokrenite svoju Outlook aplikaciju.
2. Zatim pritisnite tastere "Alt + F11" da biste pristupili prozoru VBA editora.
3. Zatim, u sljedećem prozoru, kopirajte i zalijepite VBA kod ispod u projekt “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Kasnije, trebate kliknuti na potprogram "Application_Startup" i pritisnuti tipku "F5" da biste pokrenuli ovaj makro.
5. Od tada, svaki put kada se novi sastanak doda u zadani kalendar ili promijenite postojeći sastanak, Outlook će automatski provjeriti kategorije sastanka i automatski postaviti različito vrijeme podsjetnika.

Uklonite Outlook greške

S vremena na vrijeme mogu se pojaviti razni problemi s Outlookom. Stoga je izuzetno važno da korisnici nauče kako se nositi s problemima u Outlooku. Za početak, bolje je da redovno pravite sigurnosne kopije Outlook podataka. Štaviše, ako je to priuštivo, preporučuje se da imate jaku sigurnosnu kopiju... Outlook popravak alat u blizini, kao npr DataNumen Outlook Repair. Može skenirati vašu PST datoteku kako bi otkrio probleme s Outlookom, a zatim ih s lakoćom riješio.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql oporavak i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com