Kako automatski snimiti ukupan broj dolaznih e-poruka svaki dan u Excel datoteci

Ovaj članak će vas naučiti kako dozvoliti Outlooku da automatski broji koliko ste e-poruka primili svaki dan i zapišete broj u Excel datoteku.

Mnogi korisnici moraju prebrojati ukupan broj primljenih e-poruka svaki dan. Osim toga, za praktičniju provjeru u budućnosti, mnogi su navikli snimati ukupan broj u Excel datoteku. U ovom slučaju, naravno, možete odlučiti da brojite i snimate ručno svaki dan. Međutim, to je pomalo problematično. I ponekad možete zaboraviti da to radite. Stoga morate poželjeti praktičnu metodu koja može natjerati Outlook da to automatski učini. Kao odgovor na ovaj zahtev, naučićemo vas kako da koristite VBA da biste to realizovali u nastavku.

Automatski snimajte ukupan broj dolaznih e-poruka svaki dan u Excel datoteci

1. Na samom početku pokrenite svoju Outlook aplikaciju.
2. Zatim pritisnite tasterske prečice “Alt + F11” u glavnom prozoru programa Outlook.
3. Zatim u iskačućem prozoru VBA editora otvorite projekat “ThisOutlookSession”.
4. Nakon toga, kopirajte i zalijepite sljedeće VBA kodove u ovaj projekat.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Zatim potpišite ovaj kod i promijenite postavke makronaredbe Outlooka da omogućite potpisane makroe.
6. Nakon toga, morate kreirati zadatak koji se ponavlja svakodnevno.

• Prvo kliknite na dugme "Novi zadatak" u oknu Zadaci.
• U iskačućem prozoru Novi zadatak kliknite na dugme "Ponavljanje".
• Zatim u sljedećem dijaloškom okviru odaberite “Dnevno”, “Svaki 1 dan(a)” i “Bez datuma završetka” i na kraju pritisnite “OK”.
• Kasnije promijenite temu zadatka i podsjetnik prema vašim potrebama.
• Na kraju kliknite na dugme „Sačuvaj i zatvori“.

7. Od sada, svaki put kada se podsjetnik za ovaj zadatak upozori, Outlook će automatski brojati jučer primljene e-poruke, a zatim snimiti broj u Excel datoteku, kao na sljedećem snimku ekrana:

Pobjeći od trajnog gubitka PST podataka

Niko nije voljan prihvatiti trajni gubitak PST podataka. Međutim, Outlook PST datoteka je sklona korupciji. Stoga biste trebali poduzeti dovoljne mjere opreza, kao što je pravljenje dosljedne i ažurne sigurnosne kopije PST podataka i održavanje moćne PST oporavak alat u blizini, kao DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql repair i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com