Kako automatski izvesti informacije o dolaznim porukama e-pošte u Excel datoteku pomoću Outlook VBA

Mnogi korisnici se nadaju da Outlook može automatski izvesti primarne informacije dolaznih e-poruka u Excel datoteku. Ovaj članak će razmotriti ovaj zahtjev i predstaviti brzu metodu putem Outlook VBA.

Ponekad, iz nekih razloga, kao što je statistika pošte, često ćete morati da izvezete e-poštu u Excel datoteku. Općenito, za postojeće primljene e-poruke, možete jednostavno koristiti funkciju "Uvoz i izvoz" da ih izvezete u Excel u jednom potezu. Međutim, možda čak želite da Outlook može automatski izvesti dolazne e-poruke u Excel čim stignu u vaše poštansko sanduče. Bez ikakve sumnje, ne postoji takva izvorna funkcija u Outlooku. Stoga morate koristiti druge pristupe, kao što je dodatak treće strane ili Outlook VBA. Ovdje ćemo vas naučiti kako to učiniti automatskim pomoću Outlook VBA. Čitajte dalje da biste dobili korake i odgovarajuće kodove.

Automatski izvoz informacija dolaznih e-poruka u Excel datoteku

1. Na prvom mjestu, trebali biste kreirati Excel datoteku.

• Otvorite novu Excel datoteku.
• Zatim bi trebalo da ukucate „Ne“. u ćeliji A1, "Ime pošiljaoca" u ćeliji B1, "Adresa e-pošte pošiljaoca" u ćeliji C1 i "Predmet e-pošte" u ćeliji D1 i "Vrijeme prijema" u ćeliji E1, kao na sljedećoj slici.
• Na kraju ga sačuvajte u željeno ime i željeni folder.

2. Nakon toga, trebali biste pokrenuti Outlook.
3. Zatim pritisnite tipke “Alt + F11” koje će vas dovesti do VBA editora.
4. Zatim u iskačućem prozoru trebate dvaput kliknuti na “ThisOutlookSession” na lijevoj strani.
5. Nakon toga, u prozoru projekta “ThisOutlookSession”, morate kopirati i zalijepiti sljedeće VBA kodove u njega.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Kasnije bi trebao potpisati ovaj kod.
7. Nakon toga, restart Outlook da aktivirate novi VBA projekat.
8. Na kraju, od sada pa nadalje, sve dolazne e-poruke će se automatski izvoziti u unaprijed postavljenu Excel datoteku čim stignu u vašu mapu Inbox. Excel datoteka će izgledati kao sljedeća slika:

Izbjegnite bolnu korupciju PST podataka

Outlook je zaradio mnogo pohvala zbog svojih različitih funkcija. Međutim, to ne znači da je to sigurno. I dalje se može ugroziti u bilo kojem trenutku. Na primjer, ako često nepropisno zatvarate Outlook, vrlo je vjerovatno da će vaši PST podaci biti dovedeni u opasnost. U ovom slučaju, ako želite popraviti PST podataka, morate se obratiti iskusnom alatu, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com