Kako automatski primijeniti kategorije e-pošte na sve njene odgovore i prosljeđivanje u Outlooku

Kada odgovarate ili prosljeđujete e-poštu, možda ćete htjeti primijeniti iste kategorije. U ovom članku ćemo vas naučiti da to shvatite pomoću VBA koda.

Ako ste navikli da dodeljujete iste kategorije boja originalne e-pošte svim njenim odgovorima i prosleđenjima, zašto ne dozvolite da Outlook to automatski postigne? Iako Outlook ne pruža takvu direktnu funkciju, i dalje je možete dobiti uz pomoć VBA koda. U nastavku ćemo vam izložiti detaljne korake i kod.

Automatska primjena kategorija e-pošte na sve njene odgovore i prosljeđivanje

1. Na samom početku pokrenite Outlook aplikaciju.
2. Zatim pritisnite tipke “Alt + F11” da pokrenete Outlook VBA editor.
3. Zatim kopirajte sljedeći VBA kod u projekt “ThisOutlookSession”.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Nakon toga, reztart svoj Outlook da aktivirate ovaj projekat.
5. Od tada ga možete isprobati slijedeći korake u nastavku.

• Prvo odaberite e-poštu i pritisnite dugme "Proslijedi".
• Zatim će se prikazati poruka e-pošte za prosljeđivanje u kojoj možete preći na karticu „Opcije“ i pritisnuti ikonu ekstenzije u donjem desnom uglu grupe „Više opcija“.
• Zatim, u iskačućem dijaloškom okviru „Svojstva“, možete vidjeti da je ovoj e-pošti dodijeljene iste kategorije boja kao i originalnoj e-pošti.

Popravi oštećenu Outlook datoteku

S obzirom na činjenicu da je Outlook ranjiv, morate poduzeti mnogo radnji kako biste izbjegli gubitak Outlook podataka. Na primjer, trebate periodično praviti sigurnosne kopije podataka. Osim toga, potrebno je da se čuvate nepoznatih e-poruka, uključujući ugrađene veze ili priloge. Na kraju, ali ne i najmanje važno, trebali biste se dočepati vrhunskog alata za eksterno popravljanje, npr DataNumen Outlook Repair. Može vam pomoći da izvučete maksimum podataka oštećeni Outlook fajl.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući SQL Server popraviti i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com