2 načina da odštampate liste Outlook zadataka sa različitim kategorijama na različitim stranicama

Ako ste svojim Outlook zadacima dodijelili različite kategorije boja i sada želite ispisati liste zadataka s različitim kategorijama na različitim stranicama, možete pogledati ovaj članak. Ovdje ćemo vam podijeliti 2 načina da ga dobijete.

Da biste klasifikovali i dobro upravljali svojim zadacima, možda ste primenili kategorije boja na svoje zadatke. Sada, ako želite da ispišete liste svojih zadataka sa različitim kategorijama na različitim stranicama, čitajte dalje. U nastavku ćemo vam predstaviti 2 načina da ga dobijete.

Metoda 1: Ručno štampanje liste zadataka jednu po jednu

1. Prvo, u Outlooku, pristupite oknu "Zadaci".
2. Zatim otvorite fasciklu sa zadacima.
3. Zatim pritisnite “Ctrl + E” da aktivirate traku “Traži”.
4. Nakon toga, na kartici “Traži” kliknite na dugme “Kategorizuj”.
5. Sa padajuće liste odaberite kategoriju boja.
6. Tada će na listi ostati samo zadaci sa odabranom kategorijom.
7. Sada idite na “File” > “Print” da odštampate ovu listu zadataka.
8. Zatim, na isti način, ručno odštampajte liste zadataka sa ostalim kategorijama boja jedan po jedan.

Metod 2: Paketno štampanje liste zadataka pomoću VBA

1. Na samom početku pokrenite VBA editor u skladu sa "Kako pokrenuti VBA kod u vašem Outlooku".
2. Zatim dodajte referencu na „MS Excel Object Library“ kao što je navedeno u „Kako dodati referencu biblioteke objekata u VBA".
3. Zatim kopirajte sljedeći VBA kod u modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Nakon toga, pritisnite dugme “F5” da biste odmah pokrenuli ovaj makro.
5. Kada se makro završi, liste zadataka sa različitim kategorijama će se štampati na različitim stranicama, kao što je prikazano na sledećem snimku ekrana.

Vratite vrijedne podatke iz kompromitovane PST datoteke

Ako ste podložni nedostupnoj PST datoteci, vaš sljedeći korak je nesumnjivo PST repair. U ovom slučaju, prvo možete isprobati alat za popravku inboxa. Pod uslovom da ne uspije, možete nastaviti s isprobavanjem drugog vanjskog alata, kao što je DataNumen Outlook Repair. U stanju je da oporavi PST podatke u kratkom vremenu.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com