2 brza načina da prebrojite broj istaknutih riječi u vašem Word dokumentu

U ovom članku želimo vam ponuditi 2 brza načina da prebrojite broj istaknutih riječi u vašem Word dokumentu.

S vremena na vrijeme bismo različitim bojama istakli tekstove različitih tema. U slučaju da želite da izbrojite ukupan broj istaknutih riječi, morate razumjeti da u Wordu ne postoji direktan način da se izvrši ovaj zadatak. Ali kao zaobilazno rješenje, možete odabrati bilo koju od sljedećih metoda u različitim slučajevima.

Metoda 1: Prebrojite sve istaknute riječi u različitim bojama

1. Prije svega, pritisnite “Alt+ F11” da otvorite VBA editor u Wordu.
2. Zatim kliknite na “Normalno” na lijevoj koloni.
3. Zatim kliknite na “Insert” na traci menija.
4. Na padajućem izborniku odaberite "Modul".

5. I dvaput kliknite na novi modul da ga otvorite.
6. Tamo zalijepite sljedeći makro:

Sub CountAllWordsInHighlight()
    Dim objWord As Range
    Dim nHighlightedWords As Long
    Dim objDoc As Document
 
    Application.ScreenUpdating = False
    Set objDoc = ActiveDocument
 
    With Selection
         .HomeKey Unit:=wdStory
         With Selection.Find
              .Highlight = True
 
              Do While .Execute
                       nHighlightedWords = nHighlightedWords + Selection.Range.ComputeStatistics(wdStatisticWords)
                       Selection.Collapse wdCollapseEnd
              Loop
         End With
    End With
 
    MsgBox ("The total number of highlighted words is " & nHighlightedWords & " .")
 
    Application.ScreenUpdating = True
    Set objDoc = Nothing
End Sub

7. Na kraju, ali ne i najmanje važno, kliknite na dugme “Run” ili pritisnite “F5” da izvršite kodove.

Pojavit će se okvir s porukom, kao što je dolje:

Metoda 2: Prebrojite sve istaknute riječi u određenoj boji

Kao što smo već spomenuli, na vaš Word dokument može biti primijenjeno nekoliko boja isticanja. Stoga je nekako teško dobiti broj riječi istaknutih riječi u određenoj boji. Srećom, uvijek smo se mogli osloniti na makro da obavimo neki prilagođeni zadatak.

1. Prije svega, ponovite korake iz metode 1 da biste instalirali i pokrenuli makro.
2. Zatim zamijenite ovim makroom:

Sub CountWordsInASpecificHighlightColor()
    Dim objDoc As Document
    Dim objWord As Object
    Dim nHighlightedWords As Long
    Dim strHighlightColor As String
 
    Application.ScreenUpdating = False
    Set objDoc = ActiveDocument
    nHighlightedWords = 0
    strHighlightColor = InputBox("Choose a Highlight colour (enter the value):" & vbNewLine & _
      vbTab & "Auto" & vbTab & vbTab & "0" & vbNewLine & _
      vbTab & "Black" & vbTab & vbTab & "1" & vbNewLine & _
      vbTab & "Blue" & vbTab & vbTab & "2" & vbNewLine & _
      vbTab & "BrightGreen" & vbTab & "4" & vbNewLine & _
      vbTab & "DarkBlue" & vbTab & vbTab & "9" & vbNewLine & _
      vbTab & "DarkRed" & vbTab & vbTab & "13" & vbNewLine & _
      vbTab & "DarkYellow" & vbTab & "14" & vbNewLine & _
      vbTab & "Gray25" & vbTab & vbTab & "16" & vbNewLine & _
      vbTab & "Gray50" & vbTab & vbTab & "15" & vbNewLine & _
      vbTab & "Green" & vbTab & vbTab & "11" & vbNewLine & _
      vbTab & "Pink" & vbTab & vbTab & "5" & vbNewLine & _
      vbTab & "Red" & vbTab & vbTab & "6" & vbNewLine & _
      vbTab & "Teal" & vbTab & vbTab & "10" & vbNewLine & _
      vbTab & "Turquoise" & vbTab & "3" & vbNewLine & _
      vbTab & "Violet" & vbTab & vbTab & "12" & vbNewLine & _
      vbTab & "White" & vbTab & vbTab & "8" & vbNewLine & _
      vbTab & "Yellow" & vbTab & vbTab & "7", "Pick Highlight Color")
 
    For Each objWord In objDoc.Words
        If objWord.HighlightColorIndex = strHighlightColor Then
           nHighlightedWords = nHighlightedWords + 1
        End If
    Next objWord
 
    MsgBox ("The number of highlighted words is " & nHighlightedWords & " .")
 
    Application.ScreenUpdating = True
    Set objDoc = Nothing
End Sub

3. Zatim u polju „Izaberite boju za isticanje“ unesite vrednost boje i kliknite na „U redu“. Na primjer, ovdje unosimo "7", što predstavlja žutu boju.
4. Evo sad ishoda:

Pametno riješite problem korupcije u dokumentima

S vremena na vrijeme, možete se susresti sa Oštećenje riječi. Najgore od svega je što to može dovesti do slomljenih dokumenata. Iako možete koristiti ugrađenu funkciju u Word-u za oporavak dokumenta, možete pribjeći još jednom pametnom izboru a to je da nabavite alat za popravku za vraćanje podataka u najkraćem mogućem roku.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen xls i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com