কিভাবে দ্রুত এক্সেলে একটি আউটলুক কন্টাক্ট গ্রুপের সমস্ত সদস্যের বিশদ রপ্তানি করবেন

ডিফল্টরূপে, আপনি শুধুমাত্র একটি পরিচিতি গ্রুপে সদস্যদের নাম এবং ইমেল ঠিকানা দেখতে পারেন। আপনি যদি সদস্যদের অন্যান্য বিবরণ পেতে চান, আপনি এই নিবন্ধে প্রবর্তিত উপায় ব্যবহার করতে পারেন.

আপনি যখন একটি পরিচিতি গোষ্ঠীকে খুলতে ডাবল ক্লিক করেন, তখন তার উইন্ডোতে, আপনি শুধুমাত্র গোষ্ঠীর সদস্যদের নাম এবং ইমেল ঠিকানা দেখতে পাবেন। আপনি সদস্যদের অন্যান্য বিশদ যেমন কোম্পানি, চাকরির শিরোনাম, ফোন নম্বর বা ব্যবসার ঠিকানা ইত্যাদি পেতে অক্ষম৷ সাধারণভাবে, এই বিবরণগুলি পেতে, আপনাকে আপনার পরিচিতি ফোল্ডারে সদস্যদের সাথে সম্পর্কিত পরিচিতিগুলি ম্যানুয়ালি খুঁজে বের করতে হবে৷ এটা খুব ঝামেলার। এখানে আমরা আপনাকে VBA কোডের একটি অংশ দেখাব, যা দ্রুত এই বিবরণগুলিকে এক্সেল ওয়ার্কবুকে রপ্তানি করতে পারে।

একটি পরিচিতি গ্রুপের সমস্ত সদস্যের বিশদ এক্সেলে রপ্তানি করুন

1. প্রথমে, আপনার Outlook অ্যাপ্লিকেশনটি চালু করুন।
2. তারপরে আপনাকে প্রধান আউটলুক উইন্ডোতে "Alt + F11" কী শর্টকাট টিপুন।
3. নতুন "অ্যাপ্লিকেশনের জন্য মাইক্রোসফ্ট ভিজ্যুয়াল বেসিক" উইন্ডোতে, আপনাকে একটি অ-ব্যবহারের মডিউল খুলতে হবে বা সরাসরি একটি নতুন মডিউল সন্নিবেশ করতে হবে৷
4. পরবর্তীকালে, এই মডিউলটিতে নিম্নলিখিত ভিবিএ কোডটি অনুলিপি করুন এবং আটকান।

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. এর পরে, সুবিধাজনক চেকের জন্য, আপনি দ্রুত অ্যাক্সেস টুলবার বা রিবনে নতুন VBA প্রকল্প যোগ করতে পারেন।
6. পরে আপনার আউটলুক ম্যাক্রো নিরাপত্তা স্তর কম সেট করুন।
7. শেষ পর্যন্ত, আপনি চেষ্টা করতে পারেন।

• প্রথমে, একটি পরিচিতি গ্রুপ নির্বাচন করুন।
• তারপর কুইক এক্সেস টুলবার বা রিবনে ম্যাক্রো বোতাম টিপুন।
• অবিলম্বে, ম্যাক্রো চালানো হবে.
• এটি শেষ হলে, আপনি "সম্পূর্ণ!" এর একটি প্রম্পট পাবেন!
• এর পরে, আপনি পূর্বনির্ধারিত গন্তব্য স্থানীয় ফোল্ডারে যেতে পারেন, যেখানে আপনি একটি নতুন এক্সেল ফাইল খুঁজে পেতে পারেন।
• এটি খুলুন, আপনি নিম্নলিখিত স্ক্রিনশটের মতো গ্রুপের সদস্যদের যোগাযোগের বিবরণ দেখতে পাবেন:

আউটলুক সমস্যার মুখে আতঙ্কিত হবেন না

কেউ কোনো আউটলুক সমস্যা গ্রহণ করতে ইচ্ছুক নয়, পপআপ ত্রুটি বার্তা বা কোন ব্যাপার না দূষিত আউটলুক আমার স্নাতকের. অতএব, আউটলুক সমস্যাগুলি জুড়ে আসার সময় ব্যবহারকারীরা আতঙ্কিত হবেন। আপনি যদি সেই ক্ষেত্রে শান্ত থাকতে চান তবে আপনার হাতে দুটি প্রয়োজনীয় জিনিস থাকা উচিত। একটি হল বর্তমান আউটলুক ডেটা ব্যাকআপ। অন্য একটি শক্তিশালী আউটলুক ফিক্স সফ্টওয়্যার, মত DataNumen Outlook Repair.

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় স্কয়ার পুনরুদ্ধার এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com