আপনার শব্দের মধ্যে নির্দিষ্ট পাঠ্য সম্বলিত বাক্যগুলি সন্ধান বা মুছতে 2 দ্রুত উপায়

এই নিবন্ধে, আমরা আপনাকে আপনার ওয়ার্ডে নির্দিষ্ট পাঠ্যযুক্ত বাক্যগুলি সন্ধান করতে বা মুছে ফেলার 2 টি দ্রুত উপায় সরবরাহ করব।

এটা সকলেরই জানা যে, ওয়ার্ড-এর “ফাইন্ড অ্যান্ড রিপ্লেস” ফাংশন ব্যবহার করে আমরা নির্দিষ্ট শব্দের সমস্ত উপস্থিতি সহজেই খুঁজে বের করতে পারি। এরপর সেগুলোকে হাইলাইট, প্রতিস্থাপন বা মুছে ফেলতে আমাদের কোনো সমস্যা হয় না। যেমনটা দেখছেন, এর লক্ষ্য হলো একটি শব্দ বা শব্দগুচ্ছ। তবে আজ আমরা আপনাদের নির্দিষ্ট টেক্সটযুক্ত বাক্য খুঁজে বের করা বা মুছে ফেলার একটি ম্যাক্রো পদ্ধতি সম্পর্কে জানাতে পেরে আনন্দিত।

পদ্ধতি 1: নির্দিষ্ট পাঠ্যযুক্ত রচনাগুলি সন্ধান করুন বা মুছুন

1. শুরুতে, শব্দে ভিবিএ সম্পাদককে ট্রিগার করতে "Alt + F11" টিপুন।
2. এরপরে "সাধারণ" ক্লিক করে একটি নতুন মডিউল তৈরি করুন।
3. তারপরে একটি "সন্নিবেশ" ক্লিক করুন এবং একটি নতুন পেতে "মডিউল" নির্বাচন করুন।
4. এবং ডাবল ক্লিক দিয়ে মডিউল খুলুন।
5. এখন নিম্নলিখিত কোডগুলি পেস্ট করুন:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. পরবর্তী "রান" ক্লিক করুন।
7. পাঠ্য প্রবেশ করানোর জন্য জিজ্ঞাসা করে একটি ইনপুট বাক্স থাকবে। সমস্ত বাক্যে থাকা সাধারণ পাঠ্যটি কেবল টাইপ করুন। "ওকে" ক্লিক করুন।
8. তারপরে আপনি নির্বাচনের পাঠ্য সম্বলিত একটি বাক্য দেখতে পাবেন যা একটি বার্তা বাক্সটি প্রম্পট করবে। বাক্যটি মুছতে "হ্যাঁ" এবং এটি রাখতে "না" ক্লিক করুন।
9. নিশ্চিতকরণের পর, নির্দিষ্ট লেখা সহ পরবর্তী বাক্যটি নির্বাচিত অবস্থায় থাকে। এবং সেখানে একটি নিশ্চিতকরণ বক্সও থাকে। অর্থাৎ, ম্যাক্রোটি আপনাকে পুরো ডকুমেন্টটি ধাপে ধাপে ঘুরিয়ে নির্দিষ্ট বাক্যগুলো খুঁজে বের করে এবং প্রতিবার আপনার নিশ্চিতকরণ চায়।

পদ্ধতি 2: তালিকার কোনও পাঠ্য সম্বলিত বাক্যগুলি সন্ধান করুন বা মুছুন

পদ্ধতি 1 এ ম্যাক্রোর সাহায্যে আপনি কেবল একবারে একটি শব্দ বা বাক্যাংশ সন্ধান করতে পারেন। অবশ্যই, আপনি শব্দ বা বাক্যাংশের একাধিক উদাহরণ সন্ধান করতে বারবার ম্যাক্রো চালাতে পারেন। একাধিক অনুসন্ধানের প্রয়োজন মেটাতে, আমরা আপনাকে অন্য একটি ম্যাক্রো সরবরাহ করব।

1. প্রথমে সমস্ত কাঙ্ক্ষিত লেখা একটি নতুন ডকুমেন্টে রাখুন। নিশ্চিত করুন যেন প্রতিটি লেখা একটি অনুচ্ছেদ জুড়ে থাকে এবং এর শেষে কোনো ফাঁকা স্থান না থাকে। ডকুমেন্টটি বন্ধ করে সংরক্ষণ করুন।
2. পরবর্তী পদ্ধতিতে সঠিক পদক্ষেপ সহ একটি ম্যাক্রো ইনস্টল করুন এবং চালান।
3. তারপরে এইটির সাথে ম্যাক্রো প্রতিস্থাপন করুন:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. এখন "ব্রাউজ" উইন্ডোটি খুলবে। সবেমাত্র নথিটি সংরক্ষণ করুন এবং "খুলুন" ক্লিক করুন।
5. নিম্নলিখিত পদ্ধতিটি পদ্ধতি 1-তে সমান।

দুর্নীতির দলিলগুলির সাথে ডিল করার পদ্ধতি

মূল্যবান ডেটা ক্ষতি একেবারে ধ্বংসাত্মক। এমনকি এটি আপনার ব্যবসাকেও ঝুঁকিতে ফেলতে পারে। এই ধরনের হতাশা এড়াতে আপনার একটি ধরা দরকার শব্দ ঠিক করা যত তাড়াতাড়ি সম্ভব সরঞ্জাম। এই জাতীয় সরঞ্জাম আপনাকে দস্তাবেজ দুর্নীতির সাথে যুদ্ধে জিততে সহায়তা করবে।

লেখকের ভূমিকা:

ভেরা চেন একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় এক্সেল ঠিক করুন এবং pdf মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com