আপনার ওয়ার্ড ডকুমেন্ট থেকে বিভাগগুলি উত্তোলনের 2 দ্রুত উপায়

এই নিবন্ধে, আমরা আপনাকে আপনার ওয়ার্ড ডকুমেন্ট থেকে অন্য এক বা বেশ কয়েকটিতে বিভাগগুলি উত্তোলনের 2 দ্রুত এবং সহজ উপায় সরবরাহ করব।

এটি একটি দস্তাবেজ থেকে অন্য নথিতে সামগ্রীগুলি বের করার জন্য প্রায়শই ঘটে। এবং আমাদের পূর্ববর্তী নিবন্ধে, আমরা ডকুমেন্ট থেকে পৃষ্ঠাগুলি কীভাবে বের করতে হবে তা নিয়ে আলোচনা করেছি। বিস্তারিত তথ্যের জন্য, আপনি এই নিবন্ধটি পড়তে পারেন: আপনার ওয়ার্ড ডকুমেন্ট থেকে স্বতন্ত্র পৃষ্ঠাগুলি উত্তোলনের 2 দ্রুত উপায়

আজ, আমরা আপনাকে বিভাগ দ্বারা নিষ্কাশন কিভাবে প্রদর্শন করব।    

পদ্ধতি 1: নতুন দস্তাবেজে বর্তমান বিভাগটি এক্সট্রাক্ট করুন

1. প্রথমে, লক্ষ্য অংশে কার্সারটি রাখুন।
2. ওয়ার্ডে ভিবিএ সম্পাদককে অনুরোধ করার জন্য পরবর্তী "Alt + F11" টিপুন।
3. তারপরে বাম কলামে, "নরমাল" এ ক্লিক করুন।
4. এবং মেনু বারে, "সন্নিবেশ" ক্লিক করুন।
5. তারপরে সেই ড্রপ-ডাউন মেনুতে "মডিউল" চয়ন করুন।
6. নতুন মডিউলটি খোলার জন্য ডাবল ক্লিক করুন এবং নীচের কোডগুলিকে সেখানে পেস্ট করুন:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. এরপরে, মেনু বারে "রান" ক্লিক করুন বা "F5" টিপুন।
8. তারপরে "ব্রাউজ" উইন্ডোটি পপআপ হবে। নতুন দস্তাবেজ সঞ্চয় করার জন্য একটি স্থান চয়ন করুন এবং "ঠিক আছে" ক্লিক করুন।
9. এবং "ফাইলের নাম" বাক্সে, নতুন ফাইলের জন্য নাম লিখুন এবং "ওকে" ক্লিক করুন।

এখন আপনি বিভাগটি একটি নতুন নথিতে সরিয়ে নিয়েছেন।

পদ্ধতি 2: ডকুমেন্টের প্রতিটি বিভাগ পৃথক নতুন ব্যক্তিগুলিতে সরান

এইভাবে আপনাকে নথির সমস্ত বিভাগে ব্যাচ প্রক্রিয়া করতে সহায়তা করতে পারে। অবশ্যই, আমাদের একটি ম্যাক্রোও লাগবে।

1. শুরুতে, কাঙ্ক্ষিত ডকুমেন্টটি খুলুন।
2. তারপরে ম্যাক্রো ইনস্টল এবং চালানোর জন্য পদ্ধতি 1 তে পদক্ষেপগুলি অনুসরণ করুন।
3. কেবলমাত্র এই সময়ের সাথে সেই ম্যাক্রোটিকে প্রতিস্থাপন করুন:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. তবুও, "ব্রাউজ করুন" উইন্ডোতে একটি স্টোরেজ পথ চয়ন করুন এবং "ঠিক আছে" ক্লিক করুন।

জ্বালাময় শব্দ ত্রুটিগুলি ঠিক করুন

কিছু ওয়ার্ড ত্রুটি ব্যবহার করার সময় এগুলি পাওয়া সাধারণ। বিরক্তিকর হতে পারে, আমাদের অবশ্যই সময় নিতে হবে পুনরুদ্ধার শব্দ যত দ্রুত সম্ভব. কারণ আমরা যত বেশি দেরি করব তত তীব্রভাবে ডেটা ক্ষতি হতে পারে। অতএব, এটি আগে থেকে মেরামত করার ইউটিলিটিটি ধরে রাখার পরামর্শ দেওয়া হচ্ছে।

লেখকের ভূমিকা:

ভেরা চেন একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় দূষিত xls এবং pdf মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com