VBA vasitəsilə bir qovluqdakı dublikat Outlook elementlərini necə tez silmək olar

Outlook-da təkrarlanan elementləri silmək istəyirsinizsə, onları bir-bir axtarıb silmək olduqca çətin olacaq. Bu yazı sizə Outlook VBA ilə bunu necə tez bir zamanda tamamlamağı öyrədəcək.

Əvvəlki məqaləmdə - "Outlook-da dublikat e-poçtları necə tez tapmaq və silmək olar”, siz dublikat e-poçtları tapmaq və silmək hiyləsini öyrənə bilərsiniz, bu üsulla e-məktubları əvvəlcə mövzuya, sonra qəbul edilmiş vaxta, sonra isə əlavələrə görə sıralayır və dublikatları tapmaq və son olaraq dublikatları seçib “Sil” düyməsini sıxmaq olar. Baxmayaraq ki, bu üsul zahirən bir az daha rahatdır, lakin Outlook VBA-dan istifadə ilə müqayisədə daha çətin olur. Aşağıdakı VBA kodları ilə siz e-poçtlardan, tapşırıqlardan, kontaktlardan və ya görüşlərdən asılı olmayaraq, dublikat elementləri sadəcə bir kliklə silə bilərsiniz. İndi kodları ətraflı öyrənmək üçün oxuyun.

Qovluqdakı Dublikat Outlook Elementlərini çıxarın

1. Başlamaq üçün Outlook proqramınızı işə salın.
2. Sonra "Alt + F11" düymələrini basın.
3. Sonrakı VBA redaktoru pəncərəsində istifadə olunan modulu açmaq üçün iki dəfə klikləyin və ya “Daxil et” > “Modul” vasitəsilə birbaşa yeni modul daxil edin.
4. Sonra aşağıdakı VBA kodlarını modula köçürün və yapışdırın.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Bundan sonra bu makronu rəqəmsal olaraq imzalayın və Outlook makro təhlükəsizlik səviyyənizi aşağı səviyyəyə dəyişin.
6. Daha sonra bu yeni VBA layihəsini işlədə bilərsiniz. Alətlər panelindəki "Çalış" simgesini birbaşa klikləyin.
7. Sonradan sizdən dublikat elementləri silmək istədiyiniz qovluğu seçmək tələb olunacaq.
8. Nəhayət, seçilmiş qovluqdakı dublikat elementlər bir anda silinəcək.

Zəif PST Məlumatlarını qoruyun

PST faylı korrupsiyaya qarşı həssas olduğuna görə, PST faylınızı qorumaq üçün çox səy sərf etməlisiniz. Məsələn, Outlook-un düzgün bağlanmasının qarşısını almalısınız. Bundan əlavə, bir möhkəm hazırlamaq lazımdır Outlook düzəlişi kimi alət DataNumen Outlook Repair PST-ni vaxtında xilas edə biləcək.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc bərpa edin SQL Server və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com