Hər Rəng Kateqoriyasında Outlook təyinatlarına sərf olunan ümumi vaxtı necə tez ixrac etmək olar

Hər bir rəng kateqoriyasında görüşlərə sərf etdiyiniz ümumi vaxt haqqında hesabat yaratmaq istəyirsinizsə, bu məqalədə təqdim olunan üsuldan istifadə edə bilərsiniz. Əllə saymağa ehtiyac olmadan bunu tez bir zamanda yerinə yetirməyə kömək edə bilər.

Bir çox istifadəçi fəaliyyətlərinin əksəriyyətini Outlook təqvimində qeyd etməyə alışıb. Həmçinin, onları daha asan idarə etmək və fərqləndirmək üçün hər birinə kateqoriyalar təyin edirlər. Bu halda, bəzi istifadəçilər hər rəng kateqoriyasında təqvim elementlərinə sərf olunan ümumi vaxtı göstərən hesabat yaratmaq istəyirlər. Şübhəsiz ki, əl ilə saymaq və daxil etmək çətindir. Buna görə də, burada bu tapşırığı sadə bir kliklə necə yerinə yetirə biləcəyinizi paylaşacağıq.

Hər Rəng Kateqoriyasında Randevulara sərf olunan ümumi vaxtı ixrac edin

1. İlk növbədə, Outlook proqramınızı işə salın.
2. Sonra, Outlook pəncərəsinə daxil olduqdan sonra "Alt + F11" düymələri düymələrinə toxuna bilərsiniz.
3. Daha sonra siz “Proqramlar üçün Microsoft Visual Basic” pəncərəsinə giriş əldə edəcəksiniz.
4. Növbəti addım olaraq, "Microsoft Excel Obyekt Kitabxanası"nı aktivləşdirməlisiniz. Bunu etmək üçün "Alətlər" > "İstinad" bölməsinə klikləyə bilərsiniz.
5. Sonra istifadə olunmayan modulu tapıb açmalısınız.
6. Bundan sonra aşağıdakı VBA kodunu bu modula köçürməlisiniz.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Nəhayət, alətlər panelindəki "Çalışdır" işarəsini və ya "F5" düyməsini sıxmağınızdan asılı olmayaraq, bu makronu işə sala bilərsiniz.
8. Sonra sizdən müəyyən bir təqvim seçməyiniz tələb olunacaq.
9. Seçib "OK" düyməsini basdıqdan sonra makro işləməyə davam edəcək. Bitirdikdən sonra arxa planda görünən yeni bir Excel faylı olacaq.
10. Siz daxil ola bilərsiniz. Aşağıdakı ekran görüntüsünə bənzəyəcək:

Görünüşünüz ətrafındakı potensial təhlükələrə diqqət yetirin

Outlook istifadəçiləri naməlum e-poçt qoşmaları, daxil edilmiş bağlantılar və insan səhvləri də daxil olmaqla bütün potensial risklərə diqqət yetirməlidirlər. Əks halda, Outlook istənilən vaxt xarab ola bilər. Həmçinin, müntəzəm Outlook məlumatlarının ehtiyat nüsxələrinin çıxarılması və xüsusi təmir alətinin saxlanması zəruri məsələlərdir. DataNumen Outlook Repair ən çox tövsiyə olunan təmir vasitələrindən biridir. O, edə bilər Outlook-u təmir edin bir anda problemlər.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş mdf və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com