Hər bir Outlook qovluğundakı elementlərin ümumi sayını Excel-ə necə tez ixrac etmək olar

Hər bir Outlook qovluğundakı elementlərin sayı haqqında hesabat almaq istəyirsinizsə, bu məqalədə təqdim olunan üsuldan istifadə edə bilərsiniz. O, tez hesablama aparacaq və nəticələri Excel faylına ixrac edəcək.

Əvvəlki məqaləmdə - "Outlook VBA vasitəsilə bir qovluqdakı və bütün alt qovluqlarındakı elementlərin ümumi sayını necə tez əldə etmək olar”, qovluqdakı elementlərin sayını əldə etmək üçün VBA-dan istifadə edərək metodu öyrənə bilərsiniz. Bununla belə, bütün qovluqlardakı elementləri saymaq istəyirsinizsə, hər bir qovluğu seçib makronu bir-bir işə salmalısınız. Bir az yorucudur. Buna görə də, biz sizə hesabı Excel faylına ixrac edəcək başqa bir üsul öyrədəcəyik.

Hər bir Outlook qovluğundakı elementlərin ümumi sayını Excel-ə ixrac edin

1. Əvvəlcə Outlook proqramını işə salın.
2. Sonra əsas Outlook pəncərəsində "Alt + F11" düymələrini basın.
3. Sonra istifadə olunmayan modulu açmalı olduğunuz “Proqramlar üçün Microsoft Visual Basic” pəncərəsinə daxil olacaqsınız.
4. Sonradan aşağıdakı VBA kodunu kopyalayıb bu modula yapışdırın.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Bundan sonra, Outlook makro təhlükəsizlik səviyyənizi aşağı səviyyəyə dəyişdirməlisiniz.
6. Sonra yeni əlavə edilmiş makroya qayıda və bu makronu işə salmaq üçün F5 düyməsini sıxa bilərsiniz.
7. Sonra mənbə PST faylını seçməli və "OK" düyməsini basmalısınız.
8. Makro tamamlandıqdan sonra, aşağıdakı ekran görüntüsünə bənzəyən yeni Excel faylını tapmaq üçün əvvəlcədən təyin edilmiş yerli qovluğa keçə bilərsiniz:

Narahatedici PST Səhvlərini həll edin

Yəqin ki, Outlook-dan istifadə edərkən müxtəlif problemlərlə qarşılaşmısınız. Kiçik problemləri həll etmək üçün sadəcə olaraq müraciət edə bilərsiniz inbox təmir aləti. Bununla belə, əgər problemlər o qədər ciddidirsə ki, onlar daxili alətin edə biləcəyindən artıqdırsa, siz daha güclü alətdən istifadə etməlisiniz, məsələn: DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc mdf təmiri və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com