Outlook-da müxtəlif növ işarələnmiş elementlər üçün fərqli standart xatırlatma vaxtını necə təyin etmək olar

Varsayılan olaraq, Outlook bütün növ işarələnmiş elementlər üçün tapşırıqların defolt xatırlatma vaxtını avtomatik istifadə edəcək. Bununla belə, element növü əsasında işarələnmiş elementlər üçün fərqli xatırlatma vaxtından istifadə etmək istəyirsinizsə, bu məqalədə təqdim olunan üsula müraciət edə bilərsiniz.

Outlook, element növündən asılı olmayaraq, bütün işarələnmiş elementlər üçün defolt xatırlatma vaxtını təyin etməyə imkan verir. "Fayl" menyusuna keçib "Seçimlər" düyməsini klikləyə bilərsiniz. Sonra, "Outlook Seçimləri" pəncərəsində, aşağıdakı ekran görüntüsündə göstərildiyi kimi, "Tapşırıqlar" sekmesinde "Defolt xatırlatma vaxtı" seçimini görə bilərsiniz.

Buna baxmayaraq, əksər istifadəçilər müxtəlif növ işarələnmiş elementlər üçün fərqli xatırlatma vaxtlarından, məsələn, işarələnmiş e-poçtlar üçün "9:00" və işarələnmiş əlaqələr üçün "17:30" istifadə etməyə ümid edirlər. İndi isə, aşağıdakılarda bir metodu təqdim etmək üçün bu nümunəyə diqqət yetirəcəyik.

Fərqli Bayraqlı Elementlər üçün Fərqli Defolt Xatırlatma Vaxtını Ayarlayın

1. Başlamaq üçün Outlook tətbiqini işə salın.
2. Daha sonra "-a istinad edərək Outlook VBA redaktoruna daxil olun.Outlook-da VBA kodunu necə işlətmək olar".
3. Sonrakı “Proqramlar üçün Microsoft Visual Basic” pəncərəsində aşağıdakı kodu “ThisOutlookSession” layihəsinə köçürün.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Bundan sonra, bu makronu aktivləşdirmək üçün Outlook-u yenidən başladın.
5. Bundan sonra hər dəfə e-məktubu işarələdiyiniz zaman xatırlatma vaxtı qeydin bitmə tarixində “10:00” olaraq təyin olunacaq.
6. Kontaktı işarələdiyiniz zaman, xatırlatma vaxtı qeydin bitmə tarixində “17:30” olaraq təyin ediləcək.

Outlook problemlərini çevik şəkildə həll edin

Outlook-da hər cür problemlə qarşılaşa bilərsiniz. Buna görə də, onlarla necə mübarizə aparacağınızı əvvəlcədən öyrənməlisiniz. Məsələn, Outlook tez-tez yenidən başlasa, Office-i təmir etməli və ya üçüncü tərəf əlavələrini deaktiv etməlisiniz və s. Yaxud Outlook PST-niz pozularsa, əvvəlcə cəhd edə bilərsiniz inbox təmir aləti. Uğursuz olduqda, kimi güclü xarici alətə müraciət etməyə davam edə bilərsiniz DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc mdf bərpası və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com