Çoxlu Outlook Mesajı (.msg) Fayllarından Bütün Alıcıları Necə Tez Çıxarmaq olar

Bəzi istifadəçilər Outlook e-poçtlarından saxlanan çoxlu Outlook mesaj fayllarından bütün alıcıları tez bir zamanda çıxarmaq istəyirlər. İndi bu səhost sürətli bir yanaşma paylaşmaq üçün buna baxacağıq.

Tək Outlook mesaj faylından alıcıları çıxarmaq üçün onu açmaq üçün sadəcə iki dəfə klikləyin və sonra açılan Mesaj pəncərəsində alıcıları kopyalaya bilərsiniz. Lakin, Outlook mesaj faylları toplusu ilə məşğul olmaq lazımdırsa, əl üsulu kifayət qədər səmərəli deyil. Beləliklə, daha təsirli bir yol axtara bilərsiniz. Burada sizə belə birini təqdim edəcəyik. Onun təfərrüatlarını öyrənmək üçün oxuyun.

Çoxlu Outlook Mesajı (.msg) Fayllarından Bütün Alıcıları çıxarın

1. Kimi üçüntart, uyğun olaraq Outlook VBA redaktoruna giriş əldə edin "Outlook-da VBA kodunu necə işlətmək olar".
2. Sonra, aşağıdakı VBA kodunu boş modula köçürün və yapışdırın.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Sonra kursoru birinci alt proqrama köçürün.
4. Sonra, "Çalış" düyməsini basın və ya "F5" düyməsini basın.
5. Sonra, açılan informasiya qutusunda mənbə Outlook mesajı (.msg) fayllarını ehtiva edən Windows qovluğunu seçin.
6. Seçdikdən sonra makronun işləməyə davam etməsi üçün “OK” düyməsini sıxın.
7. Makro tamamlandıqda, aşağıdakı ekran görüntüsündə göstərildiyi kimi, bütün çıxarılan alıcıların e-poçt ünvanlarını göstərən bir mesaj görünəcək.

Outlook məlumatlarınızı təhlükədən qoruyun

Outlook məlumatları, şübhəsiz ki, korrupsiyaya meyllidir. Beləliklə, Outlook məlumatlarını qorumaq olduqca çətin bir işdir. Bu, Outlook məlumatlarının müntəzəm ehtiyat nüsxəsini çıxarmaqda əzm etməyinizi tələb edir. Həmçinin, mümkünsə, ehtiyatlı və təcrübəli və peşəkar bir Outlook hazırlamaq tövsiyə olunur PST təmiri alət kimi DataNumen Outlook Repair, beləliklə, Outlook-un pozulması halında dərhal və vaxtında xilasetmə əldə edə bilərsiniz.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc bərpa edin Sql Server və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com