Outlook VBA ilə e-poçtları cavablandırmaq və yönləndirmək üçün müxtəlif şrift rənglərini avtomatik necə istifadə etmək olar

Varsayılan olaraq, Outlook-a e-poçtları cavablandırmaq və yönləndirmək üçün avtomatik olaraq müxtəlif şrift rənglərindən istifadə etməyə icazə verə bilməzsiniz. Ona görə də belə bir tələbiniz varsa, bu səhi oxuya bilərsinizost ağıllı bir yanaşma öyrənmək.

Outlook yalnız sizə məktubları cavablandırmaq və yönləndirmək üçün istifadə olunan şrifti təyin etməyə icazə verir. Siz “Fayl” > “Seçimlər”ə keçə bilərsiniz. Sonra, "Outlook Seçimləri" ndə "Mail" sekmesine keçin və "Dəftərxana ləvazimatları və şriftlər ..." düyməsini basın. Sonrakı pəncərədə siz “Mesajların cavablandırılması və ya yönləndirilməsi” bölməsində “Şrift” düyməsini görə bilərsiniz. Bunun üzərinə klikləyin və sonra e-poçtları cavablandırmaq və yönləndirmək üçün xüsusi şrift rəngi təyin edə bilərsiniz.

Bununla belə, bir çox istifadəçi e-poçtları cavablandırmaq və ya yönləndirmək üçün müxtəlif şrift rənglərindən istifadə etməyə ümid edir. Outlook bunun üçün heç bir birbaşa xüsusiyyət təqdim etməsə də, yenə də VBA kodu ilə həyata keçirilə bilər. İndi belə bir VBA kodunu əldə etmək üçün oxuyun.

E-poçtları cavablandırmaq və yönləndirmək üçün avtomatik olaraq müxtəlif şrift rənglərindən istifadə edin

1. Kimi üçüntart, Outlook proqramını işə salın.
2. Sonra VBA redaktorunu işə salın "Outlook-da VBA kodunu necə işlətmək olar".
3. Sonra, “Necə Obyekt Lib əlavə etmək olarrary VBA-da istinad", istinad əlavə edin "MS Word Obyekt Library ”.
4. Daha sonra aşağıdakı kodu “ThisOutlookSession” layihəsinə köçürün.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Bundan sonra, restart Bu makronu aktivləşdirmək üçün Outlook.
6. Nəhayət, cəhd edə bilərsiniz.

• E-poçtu seçin və ya açın.
• Sonra "Cavab ver" düyməsini basın. E-poçtu cavablandırarkən siz bəzi sözləri bədənə daxil edə bilərsiniz. Şriftin rəngi çəhrayı olmalıdır.
• Və ya "Hamısına Cavab Ver" düyməsini basın. Yeni "hamısına cavab verən" poçtda sözləri bədənə daxil edin. Şriftin rəngi mütləq yaşıldır.
• Eynilə, "İrəli" düyməsini basın. Göndərmə poçtunda yeni sözlər mavi rənglə göstəriləcək.

Etibarlı Proqram təminatına müraciət edin

Halında Outlook korrupsiyası, Most istifadəçilər Outlook bərpa proqramına müraciət edirlər. Bazarda bu cür proqramların çoxu var. Və bəziləri hətta pulsuzdur. Buna baxmayaraq, naməlum mənbələrdən olanlardan ehtiyatlı olmalısınız, çünki onlar hazırkı işi daha da pisləşdirə bilər. Etibarlı və təcrübəli bir vasitədən istifadə etməlisiniz, məsələn DataNumen Outlook Repair.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc zədələnmiş sql və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com