Gözlənilən vaxt ərzində xüsusi e-poçtun cavabını almadıqda bildirişi necə əldə etmək olar

Bu məqalə sizə müəyyən vaxt ərzində konkret e-poçtun cavabını almadığınız zaman Outlook-un avtomatik olaraq bildiriş e-poçtu göndərib-göndərməməyinizi bildirməsinə imkan vermək üçün VBA-dan istifadə edərək sürətli hiylə öyrədəcək.

Bəzən həyati əhəmiyyətli e-poçtlar üçün siz mütləq onun cavablarını gözləyəcəksiniz. Başqa sözlə, alıcının sizə ən qısa zamanda cavab verə biləcəyinə ümid etməlisiniz. Əks halda, gözlədiyiniz vaxt ərzində cavabı hələ almadığınız müddətcə, alıcıya təkrar bildiriş e-poçtu göndərəcəksiniz. Buna görə də, bu tələbə cavab olaraq, burada Outlook-un belə bir vəziyyətdə sizi avtomatik xəbərdar etməsi və xəbərdar etməsi üçün VBA istifadə edən bir üsul təqdim edəcəyik. Ətraflı addımlar və kodları əldə etmək üçün oxuyun.

Gözlənilən Vaxt ərzində Xüsusi E-poçtun Cavabını Almasanız Bildiriş Alın

1. Ən başlanğıcda, start Outlook.
2. Sonra xüsusi e-poçt üçün xüsusi xatırlatma vaxtı təyin etməlisiniz.

• Birincisi, xüsusi e-poçtun üzərinə sağ vurun.
• Sonra "Taqib et" > "Xatırlatma əlavə et" seçin.
• Dialoq qutusunda siz xatırlatma vaxtını onun cavabını almaq istədiyiniz xüsusi vaxtla eyni təyin edə bilərsiniz.

3. Bundan sonra Outlook VBA redaktoruna daxil olmaq üçün “Alt + F11” düymələrini sıxın.
4. Sonrakı yeni pəncərədə “ThisOutlookSession” layihəsini açın və ona aşağıdakı kodları kopyalayın.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Sonra bu kodu imzalayın.
6. Daha sonra rəqəmsal imzalanmış makrolara icazə vermək üçün Outlook makro parametrlərini dəyişdirin.
7. Nəhayət restart Yeni makronu aktivləşdirmək üçün Outlook. Bundan sonra Outlook aşağıdakı kimi işləyəcək:

• Xüsusi e-poçtun cavabını xatırladıcı görünməzdən əvvəl almısınızsa, Outlook avtomatik olaraq bayrağı siləcək və xatırladıcını söndürəcək.
• Xatırlatma işə salındıqda cavabı almamısınızsa, Outlook sizdən əlavə bildiriş e-poçtu göndərib göndərməməyinizi xahiş edəcək. “Bəli” seçsəniz, e-poçt göndəriləcək. “Xeyr” seçsəniz, sorğu bir anda yox olacaq.

Zəhlətökən Outlook məsələlərini həll edin

Outlook səhvlərə meylli olduğundan, qarşısını almaq üçün Outlook korrupsiyası, yalnız Scanpst.exe inbox alətinə etibar etməsəniz daha yaxşı olar. kimi başqa bir güclü və nüfuzlu təmir aləti hazırlamalısınız DataNumen Outlook Repair, Scanpst.exe-nin həll edə bilmədiyi zəhlətökən məsələləri aradan qaldıra bilər.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql korrupsiyası və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com