Outlook-da eyni məzmunlu birdən çox e-poçtu necə toplu cavablandırmaq olar

Bir çox istifadəçi Outlook-da eyni məzmunlu bir neçə seçilmiş e-poçta toplu cavab verməyə imkan verən bir həll istəyir. Outlook belə bir xüsusiyyət təqdim etməsə də, siz hələ də VBA kodunun bir parçası ilə buna nail ola bilərsiniz.

Çox sayda istifadəçinin Outlook-un bir anda birdən çox e-poçta eyni cavabı göndərməsini dəstəkləyən funksiyası olmadığından şikayətləndiyini eşitmişəm. Onlar birdən çox e-məktub seçdikdə, həm “Cavab ver”, həm də “Hamısına Cavab Ver” hərəkətləri boz rəngə çevriləcək – deaktiv olun. Bu məsələyə baxaraq, bundan sonra bu xüsusiyyəti həyata keçirmək üçün bir üsul paylaşacağıq.

Eyni məzmunlu birdən çox e-poçta toplu cavab verin

1. Əvvəlcə Outlook proqramınızı başladın.
2. Sonra, birdən çox e-poçta cavab vermək üçün istifadə etmək istədiyiniz şablon cavabı yaratmalısınız.

• Əvvəlcə yeni e-poçt yaradın.
• Sonra cavab vermək istədiyinizə əsasən bu e-poçtu tərtib edin.
• Sonra, "Fayl" düyməsini basın və "Fərqli Saxla" seçimini seçin.
• Daha sonra, yeni "Fərqli Saxla" informasiya qutusunda ad daxil edin və "Növ kimi saxla" qutusunda "Outlook Şablonu" seçin.
• Nəhayət, "OK" düyməsini basın.

3. Sonra, dəyişiklikləri saxlamadan e-poçtu bağlaya bilərsiniz.
4. Sonra "Alt + F11" düymələrini basmalısınız.
5. Bundan sonra, Outlook VBA redaktoru pəncərəsi görünəcək.
6. İndi “ThisOutlookSession” layihəsini tapıb açmalı və aşağıdakı VBA kodunu ona kopyalamalısınız.

Sub Application_ItemContextMenuDisplay(ByVal CommandBar As Office.CommandBar, ByVal Selection As Selection)
    Dim objCommandBarButton As Office.CommandBarButton
 
    If (Selection.count > 1) And (Selection.Item(1).Class = olMail) Then
       Set objCommandBarButton = CommandBar.Controls.Add(msoControlButton)
 
       'Add a "Same Reply" option to the context menu
       With objCommandBarButton
           .Style = msoButtonIconAndCaption
           .Caption = "Same Reply"
           .FaceId = 355
           .OnAction = "Project1.ThisOutlookSession.SendSameReply"
       End With
    End If
End Sub

Sub SendSameReply()
    Dim strTemplate As String
    Dim objTemplateReply As Outlook.MailItem
    Dim strHTMLBody As String
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim objReply As Outlook.MailItem
 
    'Input the name of the previously saved template
    strTemplate = InputBox("Enter the name of template message:", , "Template Reply")
    Set objTemplateReply = Application.CreateItemFromTemplate("C:\Users\Test\Documents\UserTemplates\" & strTemplate & ".oft")
    strHTMLBody = objTemplateReply.HTMLBody
 
    Set objSelection = Application.ActiveExplorer.Selection
 
    For i = objSelection.count To 1 Step -1
        Set objReply = objSelection(i).Reply
        With objReply
             .HTMLBody = strHTMLBody & objReply.HTMLBody
             .Send
        End With
    Next
End Sub

7. Nəhayət, cari pəncərəni bağlaya və bu makronu sınaya bilərsiniz.

• Əvvəlcə poçt siyahısında birdən çox e-poçt seçin.
• Sonra, onların üzərinə sağ vurun.
• Sonra, kontekst menyusunda "Eyni Cavab" seçimini seçin və vurun.
• Sonra sizdən cavab üçün istifadə olunan şablonu göstərməyiniz tələb olunacaq.
• Adı daxil etdikdən və "OK" düyməsini vurduqdan sonra eyni cavab bu seçilmiş e-poçtlara göndəriləcək.

Görünüş Korrupsiyaya Meyillidir

Outlook-un müntəzəm istifadəçisi olaraq mən müxtəlif xətalara məruz qalmışam. Buna görə də, Outlook məlumatlarımı qorumaq üçün müxtəlif tədbirlər görmüşəm. Bununla belə, Outlook-un zədələnməyə həssas olması və qəzanın proqnozlaşdırılması çətin olduğu üçün mən hər zaman hazır olmalıyam. Məsələn, məlumatımı mümkün qədər tez xilas etmək üçün əla bir bərpa alətini əlimdə saxladım – DataNumen Outlook Repair. Bacarır Outlook-u düzəldin heç bir təlaş olmadan fayl.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql korrupsiyası və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com