Outlook-da bütün oxunmuş qəbzləri toplu şəkildə necə silmək olar

Alıcıların e-poçtunuzu oxuduğunu təsdiqləmək üçün e-poçt yazarkən oxunma qəbzini tələb edə bilərsiniz. Bu vəziyyətdə, poçt qutunuz bu cür oxunma qəbzləri ilə dolu ola bilər. İndi bu yazı sizə onları necə birdəfəlik silməyi öyrədəcək.

Məqaləni oxuduqdan sonra "Outlook-da bütün çatdırılma qəbzlərini toplu şəkildə necə silmək olar", bütün oxunmuş qəbzləri toplu silmək üçün yanaşma haqqında düşünə bilərsiniz. Əslində, iki növ qəbz arasında aşkar fərq onların subyektləridir. Çatdırılma qəbzində mövzuda "Çatdırıldı", lakin oxunmuş qəbzdə "Oxudu" ifadəsi var. Buna görə də, bütün oxunmuş qəbzləri silmək üçün eyni üsuldan istifadə edə bilərsiniz. Aşağıda sizə konkret addımları ətraflı şəkildə öyrədəcəyik.

Bütün oxunmuş qəbzləri toplu silin

1. Başlanğıcda, Outlook-a başlayın.
2. Sonra "Alt + F11" vasitəsilə "Outlook VBA redaktoruna keçin"Outlook-da VBA kodunu necə işlətmək olar".
3. Sonra, yeni pəncərədə boş bir modul açın və ona aşağıdakı kodu daxil edin.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Bundan sonra, ilk alt proqrama klikləyin.
5. Nəhayət, "F5" düyməsini basın.
6. Bir anda, makro Outlook-dan bütün oxunmuş qəbzləri silmək üçün işləyəcək.
7. Bitirdikdə, aşağıdakı ekran görüntüsü kimi, nəticə haqqında məlumat alacaqsınız.
8. Hazırda poçt qovluqlarınızı yoxlaya bilərsiniz. Bütün oxunuş qəbzləri getdi.

Outlook məlumatlarını müdafiə edin

Outlook faylının korrupsiyaya qarşı həssas olmasına baxmayaraq, biz onu qorumaq üçün tədbirlər görə bilərik. Məsələn, biz Outlook faylını kiçik ölçüdə saxlamalı, onu zərərli amillərdən qorumalı və müntəzəm olaraq ehtiyat nüsxəsini çıxarmalıyıq. Ən nəhayət, güclü xarici PST təmir aləti hazırlasanız yaxşı olar DataNumen Outlook Repair. Təmirə böyük təsir göstərəcək korlanmış Outlook file.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql təmiri və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com