Outlook e-poçtlarını çap etmək üçün xüsusi bir printerdən necə istifadə etmək olar

Siz e-poçtları çap etmək üçün Outlook-u xüsusi qeyri-defolt printerdən istifadə etmək üçün konfiqurasiya edə bilməzsiniz. Ancaq bu yazıda Outlook VBA ilə buna nail olmağın bir üsulunu sizə göstərəcəyik.

Kompüteriniz bu kompüterdəki bütün proqramlara tətbiq olunacaq printeri defolt olaraq təyin etməlidir. Bu halda, e-poçtları Outlook-da qeyri-standart printer vasitəsilə çap etmək istəyirsinizsə, hər dəfə çap edərkən printeri dəyişdirməlisiniz. Bu, olduqca əziyyətlidir. Buna görə də, aşağıdakı məqalələrdə hər dəfə printeri dəyişməyə ehtiyac olmadan e-poçtlar üçün xüsusi printerdən avtomatik istifadə etmək üçün bir vasitə paylaşacağıq.

E-poçtları Çap etmək üçün Xüsusi Printerdən Avtomatik istifadə edin

1. Ən başında, Outlook tətbiqinizi başladın.
2. Sonra, əsas Outlook pəncərəsində "Alt + F11" düymələrini basın.
3. Növbəti addım olaraq, "Microsoft Visual Basic for Applications" pəncərəsində əvvəlcə "Microsoft Word obyekt kitabxanası"nı aktivləşdirməlisiniz. Bunu etmək üçün "Alətlər" > "İstinad" bölmələrinə klikləyin.
4. Sonra boş modula daxil olmalısınız.
5. Sonradan aşağıdakı VBA kodunu kopyalayıb bu modula yapışdırın.

Sub PrintEmail()
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objWordApp As Word.Application
    Dim strTempFolder As String
    Dim strMailDocument As String
    Dim objMailDocument As Word.Document
    Dim strPrinter As String

    Select Case Application.ActiveWindow.Class
           Case olInspector
                Set objItem = ActiveInspector.CurrentItem
           Case olExplorer
                Set objItem = ActiveExplorer.Selection.Item(1)
    End Select
 
    If TypeOf objItem Is MailItem Then
       Set objMail = objItem
 
       Set objWordApp = CreateObject("Word.Application")
       strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
       strMailDocument = strTempFolder & "\" & Format(Now, "yyyymmddssnn") & ".doc"
       objMail.SaveAs strMailDocument, olDoc
 
       Set objMailDocument = objWordApp.Documents.Open(strMailDocument)
       objWordApp.Visible = True
       objMailDocument.Activate
 
       strPrinter = objWordApp.ActivePrinter
       'Change to the name of specific printer
       objWordApp.ActivePrinter = "Specific Printer"
       objWordApp.PrintOut Range:=wdPrintAllDocument, Item:=wdPrintDocumentContent
       objWordApp.ActivePrinter = strPrinter
 
       objMailDocument.Close False
       objWordApp.Quit
       Kill strMailDocument
    End If
End Sub

6. Bundan sonra cari pəncərəni bağlaya bilərsiniz.
7. Sonra "Fayl" menyusuna gedin və "Seçimlər" düyməsini basın.
8. "Outlook Seçimləri" pəncərəsində, "Tez Giriş Alətlər Paneli" sekmesine keçin və hər zamanki kimi Tez Giriş Alətlər Panelinə yeni makro əlavə edin.
9. Nəhayət, bu VBA layihəsini sınaya bilərsiniz.

• Əvvəlcə çap etmək istədiyiniz e-poçtu seçin və ya açın.
• Sonra, Tez Giriş Alətlər Panelində makro düyməsini basın.
• E-poçt xüsusi printer tərəfindən dərhal çap olunacaq.

10. Bundan sonra e-poçtları xüsusi printerdə çap etmək üçün sadəcə bu makrodan istifadə edə bilərsiniz.

Qəza Korrupsiyasından Sonra Görünüşü bərpa edin

Outlook məlumatlarınızın itirilməsinin qarşısını almaq üçün çox səy göstərməlisiniz. Məsələn, PST faylınızın ehtiyat nüsxəsini müntəzəm olaraq çıxarmalısınız. Əlbəttə ki, xarici təmir aləti kimi bir vasitə əldə etməyiniz tövsiyə olunur. DataNumen Outlook Repair. Mümkündür PST-ni düzəldin səhvləri aradan qaldırın və sizin üçün maksimum Outlook məlumatını bərpa edin.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql bərpa edin və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com