Fərqli Rəng Kateqoriyalarında Outlook Görüşləri üçün Fərqli Xatırlatma Vaxtını Avtomatik Quraşdırmaq olar

Outlook görüşlərini rəng kateqoriyalarına görə təsnif edirsinizsə və müxtəlif rəng kateqoriyalarında görüşlər üçün fərqli xatırlatma vaxtını təyin etmək istəyirsinizsə, bu məqaləyə müraciət edə bilərsiniz. Burada Outlook VBA ilə həyata keçirməyi sizə öyrədəcəyik.

Məsələn, görüşləri iki qrupa bölürsünüz. Biri görüş yeri çox uzaqda olduğu üçün "Kənar" rəng kateqoriyasında, digəri isə yer burada olduğu üçün "Yerində" rəng kateqoriyasındadır. İndi Outlook-un "kənar" görüşün xatırlatma vaxtını başlamazdan 1 saat əvvəl, "yerində" görüşün başlamazdan 15 dəqiqə əvvəl avtomatik olaraq təyin etməsini istəyirsiniz. Bu tələbi nəzərə alaraq, bundan sonra sürətli bir metod paylaşacağıq.

Müxtəlif Rəng Kateqoriyalarında Görüşlər üçün Avtomatik Fərqli Xatırlatma qurun

1. Başlamaq üçün Outlook proqramınızı işə salın.
2. Sonra VBA redaktoru pəncərəsinə daxil olmaq üçün “Alt + F11” düymələrini sıxın.
3. Sonra, növbəti pəncərədə aşağıdakı VBA kodunu kopyalayıb “ThisOutlookSession” layihəsinə yapışdırın.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Daha sonra, bu makronu işə salmaq üçün "Application_Startup" altproqramına daxil olmalı və "F5" düyməsini basmalısınız.
5. O vaxtdan bəri, hər dəfə defolt təqvimə yeni görüş əlavə olunduqda və ya siz mövcud görüşü dəyişdikdə, Outlook görüşün kateqoriyalarını avtomatik yoxlayacaq və fərqli xatırlatma vaxtını avtomatik təyin edəcək.

Outlook səhvlərini aradan qaldırın

Outlook-da zaman-zaman müxtəlif problemlər yarana bilər. Buna görə də, istifadəçilərin Outlook problemlərinin öhdəsindən necə gələcəyini öyrənməsi olduqca vacibdir. Başlanğıc üçün, Outlook məlumatlarının müntəzəm ehtiyat nüsxələrini çıxarmaq daha yaxşıdır. Bundan əlavə, əgər əlverişlidirsə, güclü bir ehtiyat nüsxəsini saxlamaq tövsiyə olunur Outlook təmiri kimi yaxınlıqdakı alət DataNumen Outlook Repair. O, Outlook problemlərini anlamaq və sonra onları asanlıqla həll etmək üçün PST faylınızı skan edə bilər.

Müəllif Giriş:

Shirley Zhang məlumatların bərpası üzrə mütəxəssisdir DataNumendaxil olmaqla məlumatların bərpası texnologiyaları üzrə dünya lideri olan , Inc sql bərpa və Outlook təmiri proqram məhsulları. Ətraflı məlumat üçün ziyarət edin www.datanumen.com